プチコン：プログラムリスト

WALL by ノトホホ

　雑誌『日経ソフトウエア』10月号（'11年8月24日発売）連動企画！　第２特集「『プチコン』でニンテンドー3DS/DSiゲームプログラミング入門」に掲載される……かもしれなかったプログラムのリストをここで公開するぞ。
　この『WALL』はサイドビューの縦スクロールアクションゲーム。十字ボタン左右で移動、Ａボタンでジャンプして、塔のカギを取って出口をめざそう。
　ガイコツにぶつかれば倒せるものの、LIFEが減ってしまう。減ったLIFEは薬を取れば回復するが、油断は禁物だ。足場から落ちて画面より下に行ってしまうと、その場でゲームオーバーになってしまうぞ。
作ったのはこの人

ノトホホ
Twitter
おなじみ「日曜プログラマーのプロ」ことスマイルブーム社長。サイドビューのジャンプ処理を作るたびにいつも「ここは前回どう作ってたっけ？」と忘れていて苦労するので、今回は自分でもこのリストを見て思い出せるように、と気合が入っているとか。
CHECK POiNT

なにか説明がおかしい気がするんだけど……「掲載されるかもしれなかった」？
うん、雑誌に載ると思って気合を入れすぎて、誌面スペースを取りすぎるリストになっちゃったんだ。簡単に言うとボツになったということかな。
載ってねェのかよ！　ちょっとは考えてプログラムしやがれ！
温情で写真１枚くらいは掲載されるそうじゃが……。もっとも、読者にわかりやすいよう整理した結果、長いプログラムになってしまったと言えんこともなくはないかもしれん。
ジャンプの処理や、最初から最後まで変数の値で一元管理しとる画面遷移など、リストを読むと参考になるハズじゃぞ。
このプログラムは載らないけど、『日経ソフトウエア』10月号（'11年8月24日発売）でプチコン特集は本当に掲載！　ショートプログラムでいろんなテクニックが解説される予定だよ。
諸君がここを読んでいるのが発売期間ならもちろん今月号をスグ買うのがオススメじゃが、すでに次の号が出ているというときはバックナンバーの販売もあるのじゃぞ。
シット、魂を売り渡したみてえな宣伝臭さがしやがるぜ！
プログラムリスト


’┌──────────────────────┐
’│ニッケイソフトウェア　フ゜チコン　トクシュウ│
’├──────────────────────┤
’│　（ｃ）ＳｍｉｌｅＢｏｏｍ　Ｃｏ．Ｌｔｄ．　│
’└──────────────────────┘
ＣＬＥＡＲ
ＶＩＳＩＢＬＥ　１，１，０，０，０，０
ＣＯＬＯＲ　０：ＣＬＳ
ＰＲＩＮＴ”Жチョット　マッテテネ．．．”
ＧＰＡＧＥ　０：ＧＣＬＳ　０
ＳＰＰＡＧＥ　０：ＳＰＣＬＲ
ＢＧＰＡＧＥ　０：ＧＯＳＵＢ　＠ＢＧＣＬＲ
ＧＯＳＵＢ　＠ＣＨＲＣＯＰＹ
’－－－－－－－－－－－－－－－－－－　メモリ－ショキカ
ＭＡＰＭＡＸ＝１００：ＳＴＧＭＡＸ＝３
ＤＩＭ　Ｍ＄（ＭＡＰＭＡＸ）
ＷＡＬＬＭＡＸ＝９：ＷＡＬＬＳＴ＝８
ＳＰＣ＝７１７：ＢＬＯＣＫ＝７２１：ＰＲ＝２
ＤＩＭ　Ｗ（ＷＡＬＬＭＡＸ，ＷＡＬＬＳＴ）
ＧＯＳＵＢ　＠ＳＥＴＷＡＬＬ
ＯＢＪＭＡＸ＝２０：＿ＭＡＸ＝１０
＿Ｘ＝０：＿Ｙ＝１：＿Ｗ＝２：＿Ｈ＝３：＿Ｓ＝４
＿Ｄ＝５：＿Ｎ＝６：＿Ｔ＝７：＿Ｏ＝８：＿Ｂ＝９
ＤＩＭ　Ｏ（ＯＢＪＭＡＸ，＿ＭＡＸ）
’－－－－－－－－－－－－－－－－－－－　リセットル－フ゜
＠ＲＥＳＥＴ
ＭＣ＝０：ＦＬ＝－１：ＲＱ＝０
ＳＴＧ＝１：ＳＣＴＯＰ＝５０００
’－－－－－－－－－－－－－－－－－－－－　メインル－フ゜
＠ＭＡＩＮＬＯＯＰ
ＯＢ＝ＢＴ：ＢＴ＝ＢＵＴＴＯＮ（）
ＢＩ＝ＢＴ　ＡＮＤ　（ＮＯＴ　ＯＢ）
ＧＯＳＵＢ　＠ＦＬＯＷ
ＭＣ＝ＭＣ＋１：ＶＳＹＮＣ　１
ＩＦ　ＢＩ！＝１０２４　ＴＨＥＮ　＠ＭＡＩＮＬＯＯＰ
’－－－－－－－－－－－－－－－－－－－－　シュウリョウ
ＣＯＬＯＲ　０：ＣＬＳ：ＧＣＬＳ　０：ＢＧＭＳＴＯＰ
ＦＯＲ　Ｉ＝０　ＴＯ　１９１
　ＣＯＬＩＮＩＴ　”ＧＲＰ”，Ｉ
ＮＥＸＴ
ＶＩＳＩＢＬＥ　１，１，０，０，０，０
ＰＲＩＮＴ”Жマタアソンテ゛ネ！”
ＥＮＤ

’■カ゛メンセンイ
’───────────────────────────
＠ＦＬＯＷ
ＩＦ　ＦＬ＝＝ＲＱ　ＴＨＥＮ　＠ＦＬＳＫＩＰ
ＦＬ＝ＲＱ
ＯＮ　ＦＬ　ＧＯＳＵＢ　＠ＴＩ，＠ＯＩ，＠ＧＩ，＠ＣＩ
＠ＦＬＳＫＩＰ
ＯＮ　ＦＬ　ＧＯＳＵＢ　＠ＴＭ，＠ＯＭ，＠ＧＭ，＠ＣＭ
ＲＥＴＵＲＮ

’■ＦＬ＝０：タイトル
’───────────────────────────
＠ＴＩ
ＶＩＳＩＢＬＥ　０，１，０，０，０，０
ＣＬＳ：Ｓ＄＝”　　　　　　　　”：ＢＧＭＰＬＡＹ　１５
ＬＯＣＡＴＥ　５，３：ＣＯＬＯＲ　１
？”ニッケイソフトウェア　フ゜チコン　トクシュウ”
ＰＲＩＮＴ：ＣＯＬＯＲ　０
？　Ｓ＄；”┌──────────────┐”
？　Ｓ＄；”│┌┐┌┐┌──┐┌┐　┌┐　│”
？　Ｓ＄；”││├┤││┌┐│││　││　│”
？　Ｓ＄；”││││││├┤││└┐│└┐│”
？　Ｓ＄；”│└──┘└┘└┘└─┘└─┘│”
？　Ｓ＄；”└──────────────┘”
？　Ｓ＄；”シ゛ャンフ゜アクションケ゛－ム！”
ＬＯＣＡＴＥ　４，２２：ＣＯＬＯＲ　１
？”（Ｃ）２０１１　ＳｍｉｌｅＢｏｏｍ　Ｃｏ．Ｌｔｄ．”
’－－－－－－－－－－－－－－－－－　ク゛ラテ゛－ション
ＦＯＲ　Ｉ＝０　ＴＯ　１９１
　Ｃ＝（２５５－Ｉ）＊２：ＧＯＳＵＢ　＠ＭＫＣＯＬ
　Ｂ＄＝Ｃ＄：Ｃ＝Ｉ＊１．５：ＧＯＳＵＢ　＠ＭＫＣＯＬ
　Ｇ＄＝Ｃ＄：Ｃ＝Ｉ／２：ＧＯＳＵＢ　＠ＭＫＣＯＬ
　ＣＯＬＳＥＴ　”ＧＲＰ”，Ｉ＋１，Ｃ＄＋Ｇ＄＋Ｂ＄
　ＧＬＩＮＥ　０，Ｉ，２５５，Ｉ，Ｉ＋１
ＮＥＸＴ
ＳＴＧ＝０：ＥＮＤＹ＝１９２＋１５
ＶＩＳＩＢＬＥ　１，１，０，０，０，１
ＲＥＴＵＲＮ
’－－－－－－－－－－－－－－－－－－　タイトル　メイン
＠ＴＭ
Ｓ＄＝”　　　　　　　　　　　　　　”
ＩＦ　（ＭＣ　ＡＮＤ　１５）＞７　ＴＨＥＮ　＠ＴＭＰＵＴ
Ｓ＄＝”ＰＵＳＨ　А　ＢＵＴＴＯＮ”
＠ＴＭＰＵＴ
ＬＯＣＡＴＥ　９，１６：ＣＯＬＯＲ　１３
ＰＲＩＮＴ　Ｓ＄：ＣＯＬＯＲ　０
ＩＦ　ＢＩ＝＝１６　ＴＨＥＮ　ＲＱ＝１
ＲＥＴＵＲＮ

’■ＦＬ＝１：ケ゛－ムマエ
’───────────────────────────
＠ＯＩ
ＣＬＳ：ＢＧＭＰＬＡＹ　４
ＶＩＳＩＢＬＥ　１，１，０，０，０，１
ＬＯＣＡＴＥ　１２，１０：ＣＯＬＯＲ　０
ＰＲＩＮＴ”ＳＴＡＧＥ：”；ＳＴＧ＋１
ＭＯＹ＝０：ＭＶＹ＝０：ＯＶＹ＝０：ＭＰＹ＝０
ＯＢＪ＝０：ＧＯＳＵＢ　＠ＯＢＪＩＮＩＴ
ＢＧＯＦＳ　０，０，０：ＢＧＯＦＳ　１，０，０
ＧＯＳＵＢ　＠ＢＧＣＬＲ
ＧＯＳＵＢ　＠ＳＥＴＭＡＰ
ＶＩＳＩＢＬＥ　１，１，１，１，１，１
ＷＣ＝６０＊２：ＲＥＴＵＲＮ
’－－－－－－－－－－－－－－－－　ケ゛－ムマエ　メイン
＠ＯＭ
’－－－　キ゛ョウタンイテ゛　マッフ゜ヒョウシ゛
ＩＦ　ＭＰＹ＜１２　ＴＨＥＮ　＠ＰＵＴＬＩＮＥ
’－－－　マッフ゜カキオワッタラ　ユウコウ
＠ＯＭＳＫＩＰ
ＷＣ＝ＷＣ－１：ＩＦ　ＷＣ＝＝０　ＴＨＥＮ　ＲＱ＝２
ＩＦ　ＢＩ＝＝１６　ＴＨＥＮ　ＲＱ＝２
ＲＥＴＵＲＮ

’■ＦＬ＝３：ケ゛－ムアト
’───────────────────────────
＠ＣＩ
ＣＬＳ：ＶＩＳＩＢＬＥ　１，１，１，１，１，１
ＬＳ＝０：Ｘ＝１２：Ｂ＝６：Ｃ＄＝”ＧＡＭＥＯＶＥＲ”
ＩＦ　ＬＩＦＥ＜０　ＧＯＴＯ　＠ＣＩＥＮＤ
ＬＳ＝１：Ｘ＝１３：Ｂ＝５：Ｃ＄＝”ＣＬＥＡＲ！”
＠ＣＩＥＮＤ
ＢＧＭＰＬＡＹ　Ｂ：ＣＯＬＯＲ　０
ＬＯＣＡＴＥ　Ｘ，１０：ＰＲＩＮＴ　Ｃ＄
ＲＥＴＵＲＮ
’－－－－－－－－－－－－－－－－　ケ゛－ムアト　メイン
＠ＣＭ
ＯＮ　ＬＳ　ＧＯＴＯ　＠ＣＭＧ，＠ＣＭＣ，＠ＣＭＥ
’－－－　ＬＳ＝２：エンテ゛ィンク゛
＠ＣＭＥ
ＩＦ　（ＭＣ　ＡＮＤ　７）　ＴＨＥＮ　ＲＥＴＵＲＮ
ＩＦ　ＥＣ＜ＲＬＣ　ＴＨＥＮ　ＲＥＡＤ　Ｃ＄：？　Ｃ＄
ＥＣ＝ＥＣ＋１
ＩＦ　ＥＣ＞＝ＲＬＣ＋６０　ＴＨＥＮ　ＲＱ＝０
ＲＥＴＵＲＮ
’－－－　ＬＳ＝０：ケ゛－ムオ－ハ゛－
＠ＣＭＧ
ＩＦ　ＢＩ＝＝１６　ＴＨＥＮ　ＲＱ＝０
ＲＥＴＵＲＮ
’－－－　ＬＳ＝１：クリア
＠ＣＭＣ
ＧＯＳＵＢ　＠ＣＭＧ：ＩＦ　ＲＱ　ＴＨＥＮ　ＲＥＴＵＲＮ
’－－－　ステ－シ゛コウシン
ＳＴＧ＝ＳＴＧ＋１：ＲＱ＝１
ＩＦ　ＳＴＧ＜ＳＴＧＭＡＸ　ＴＨＥＮ　ＲＥＴＵＲＮ
’－－－　エンテ゛ィンク゛カイシ
ＬＳ＝２：ＥＣ＝０：ＲＱ＝３
ＲＥＳＴＯＲＥ　＠ＳＴＡＦＦ：ＲＥＡＤ　ＲＬＣ
ＣＬＳ：ＢＧＭＰＬＡＹ　７
ＶＩＳＩＢＬＥ　１，１，０，０，０，０
ＲＥＴＵＲＮ
’－－－　
＠ＳＴＡＦＦ
ＤＡＴＡ　３３
ＤＡＴＡ　”■ＳＴＡＦＦ”
ＤＡＴＡ　”－－－－－－－－－－－－－－－－－－－－－”
ＤＡＴＡ　”◎ＰＲＯＧＲＡＭ”
ＤＡＴＡ　”　　ＳｍｉｌｅＢｏｏｍ”
ＤＡＴＡ　””
ＤＡＴＡ　”◎ＤＥＳＩＧＮ”
ＤＡＴＡ　”　　ＳｍｉｌｅＢｏｏｍ”
ＤＡＴＡ　””
ＤＡＴＡ　”◎ＰＬＡＮＩＮＧ”
ＤＡＴＡ　”　　ＳｍｉｌｅＢｏｏｍ”
ＤＡＴＡ　””，””，””，””，””
ＤＡＴＡ　””，””，””，””，””
ＤＡＴＡ　””，””，””，””，””
ＤＡＴＡ　””，””，””，””，””
ＤＡＴＡ　”┌──────────┐”
ＤＡＴＡ　”│ＴＨＡＮＫ　ＹＯＵ！│”
ＤＡＴＡ　”└──────────┘”

’■ＦＬ＝２：ケ゛－ム
’───────────────────────────
＠ＧＩ
’－－－　ヘンスウショキカ
ＴＩＭＥ＝９９＊６０：ＬＩＦＥ＝３：ＳＣ＝０：ＤＭＧ＝０
ＳＰＤ＝２：ＪＶＹ＝１：ＪＣ＝０：ＤＭＧＣ＝０
Ｏ（０，＿Ｎ）＝６４
’－－－　カ゛メンシ゛ュンヒ゛
ＣＬＳ：ＣＯＬＯＲ　１：ＢＧＭＰＬＡＹ　ＭＡＰＢＧＭ
ＬＯＣＡＴＥ　２９，　１：ＰＲＩＮＴ”ＴＯＰ”
ＬＯＣＡＴＥ　２７，　４：ＰＲＩＮＴ”ＳＣＯＲＥ”
ＬＯＣＡＴＥ　２８，　７：ＰＲＩＮＴ”ＴＩＭＥ”
ＬＯＣＡＴＥ　２８，１０：ＰＲＩＮＴ”ＬＩＦＥ”
ＬＯＣＡＴＥ　２７，１３：ＰＲＩＮＴ”ＳＴＡＧＥ”
ＧＯＴＯ　＠ＰＵＴＳＴＡＴ
’－－－－－－－－－－－－－－－－－－　ケ゛－ム　メイン
＠ＧＭ
ＧＯＳＵＢ　＠ＢＧＳＣＲＬ
ＩＸ＝０
’－－－－－－－－－－－－－－－－－－－－－－－－－－－
＠ＧＭＬＯＯＰ
Ｔ＝Ｏ（ＩＸ，＿Ｔ）
ＩＦ　Ｔ＝＝０　ＴＨＥＮ　＠ＧＭＳＫＩＰ
’－－－　ハイレツカラコヒ゜－
ＰＸ＝Ｏ（ＩＸ，＿Ｘ）：ＰＹ＝Ｏ（ＩＸ，＿Ｙ）
ＯＸ＝ＰＸ：ＯＹ＝ＰＹ
ＳＴ＝Ｏ（ＩＸ，＿Ｓ）：ＮＭ＝Ｏ（ＩＸ，＿Ｎ）
ＶＸ＝Ｏ（ＩＸ，＿Ｗ）：ＶＹ＝Ｏ（ＩＸ，＿Ｈ）
’－－－　スクロ－ルフ゛ン　コウリョ
ＰＹ＝ＰＹ＋ＯＶＹ
’－－－　オフ゛シ゛ェクト　セイキ゛ョ
ＧＯＳＵＢ　＠ＯＢＪＭＯＶＥ
’－－－　ハイレツヘモト゛ス
Ｏ（ＩＸ，＿Ｗ）＝ＶＸ：Ｏ（ＩＸ，＿Ｈ）＝ＶＹ
Ｏ（ＩＸ，＿Ｓ）＝ＳＴ：Ｏ（ＩＸ，＿Ｎ）＝ＮＭ
Ｏ（ＩＸ，＿Ｘ）＝ＰＸ：Ｏ（ＩＸ，＿Ｙ）＝ＰＹ
ＳＰＣＨＲ　ＩＸ，ＮＭ
ＳＰＯＦＳ　ＩＸ，ＰＸ－８，ＰＹ－１６
’－－－－－－－－－－－－－－－－－－－－－－－－－－－
＠ＧＭＳＫＩＰ
ＩＸ＝ＩＸ＋１
ＩＦ　ＩＸ＜ＯＢＪＭＡＸ　ＴＨＥＮ　＠ＧＭＬＯＯＰ
’－－－
ＴＩＭＥ＝ＴＩＭＥ－１
ＩＦ　（ＭＣ　ＡＮＤ　６３）　ＴＨＥＮ　ＲＥＴＵＲＮ
ＧＯＴＯ　＠ＰＵＴＳＴＡＴ

’■オフ゛シ゛ェクト
’───────────────────────────
＠ＯＢＪＭＯＶＥ
ＯＮ　Ｔ　ＧＯＴＯ　＠ＯＦ，＠ＯＰ，＠ＯＥ，＠ＯＤ

’－－－　Ｔ＝０：ナシ
＠ＯＦ
ＲＥＴＵＲＮ

’－－－　Ｔ＝３：ト゛ア
＠ＯＤ
ＩＦ　Ｏ（０，＿Ｓ）　ＴＨＥＮ　ＲＥＴＵＲＮ
ＧＯＳＵＢ　＠ＣＨＫＨＩＴ
ＩＦ　Ｃ　ＴＨＥＮ　ＲＱ＝３
ＲＥＴＵＲＮ

’－－－　フ゜レイヤ－トノセッショク
＠ＣＨＫＨＩＴ
Ｙ＝ＡＢＳ（ＰＬＹ－ＰＹ）
ＩＦ　Ｙ＞８　ＴＨＥＮ　Ｃ＝０：ＲＥＴＵＲＮ
Ｘ＝ＡＢＳ（ＰＬＸ－ＰＸ）
ＩＦ　Ｘ＞６　ＴＨＥＮ　Ｃ＝０：ＲＥＴＵＲＮ
Ｃ＝１：ＲＥＴＵＲＮ

’－－－　Ｔ＝２：テキ
＠ＯＥ
ＩＦ　ＰＹ＞ＥＮＤＹ　ＴＨＥＮ　＠ＤＥＡＤ
ＯＮ　ＳＴ　ＧＯＴＯ　＠ＯＥ０，＠ＯＥ１
’－－－
ＰＹ＝ＰＹ＋ＶＹ：ＶＹ＝ＶＹ＋１：ＲＥＴＵＲＮ
’－－－
＠ＯＥ０
ＳＴ＝１：ＶＸ＝１
ＩＦ　ＲＮＤ（６）＜３　ＴＨＥＮ　ＶＸ＝－１
’－－－
＠ＯＥ１
ＧＯＳＵＢ　＠ＣＨＫＨＩＴ
ＩＦ　Ｃ　ＴＨＥＮ　＠ＥＮＥＤＥＡＤ
’－－－
ＮＭ＝１２８：ＩＦ　ＶＸ＜０　ＴＨＥＮ　ＮＭ＝１３２
ＰＸ＝ＰＸ＋ＶＸ
ＧＯＳＵＢ　＠ＣＨＫＳＤ　：’サユウホセイ
ＩＦ　Ｃ　ＴＨＥＮ　＠ＯＥＲＥＶ
ＧＯＳＵＢ　＠ＣＨＫＦＬ　：’アシモトカクニン
ＩＦ　Ｃ　ＴＨＥＮ　ＲＥＴＵＲＮ
＠ＯＥＲＥＶ
ＰＸ＝ＯＸ：ＳＴ＝０：ＲＥＴＵＲＮ

’－－－　テキシホ゛ウ
＠ＥＮＥＤＥＡＤ
ＳＴ＝２：ＶＹ＝－１０：ＢＥＥＰ　６，－４０００
ＳＰＣＨＲ　ＩＸ，ＮＭ，１５，０，１，ＰＲ
’－－－　フ゜レイヤ－ヘタ゛メ－シ゛
Ｏ（０，＿Ｎ）＝８８：ＤＭＧＣ＝１６
ＬＩＦＥ＝ＬＩＦＥ－１
ＩＦ　ＬＩＦＥ＞＝０　ＴＨＥＮ　＠ＥＤＥＮＤ
ＳＰＣＨＲ　０，８８：ＲＱ＝３
＠ＥＤＥＮＤ
ＧＯＴＯ　＠ＰＵＴＬＩＦＥ

’－－－
＠ＤＥＡＤ
Ｔ＝０：Ｏ（ＩＸ，＿Ｔ）＝Ｔ：ＢＥＥＰ　１４
ＩＦ　ＩＸ　ＴＨＥＮ　ＲＥＴＵＲＮ
ＲＱ＝３：ＬＩＦＥ＝－１：ＧＯＴＯ　＠ＰＵＴＬＩＦＥ

’－－－　Ｔ＝１：フ゜レイヤ－
＠ＯＰ
ＩＦ　ＤＭＧＣ＝＝０　ＴＨＥＮ　＠ＯＰ２
ＤＭＧＣ＝ＤＭＧＣ－１：ＲＥＴＵＲＮ
’
＠ＯＰ２
Ｖ＝０：Ｎ＝ＮＭ
ＩＦ　ＢＴ　ＡＮＤ　４　ＴＨＥＮ　Ｖ＝－１：Ｎ＝７２
ＩＦ　ＢＴ　ＡＮＤ　８　ＴＨＥＮ　Ｖ＝１：Ｎ＝６４
ＮＭ＝Ｎ
ＯＮ　ＳＴ　ＧＯＳＵＢ　＠ＰＷ，＠ＰＪ，＠ＰＨ，＠ＰＦ
’－－－
ＩＦ　ＰＹ＞ＥＮＤＹ　ＴＨＥＮ　＠ＤＥＡＤ
ＧＯＳＵＢ　＠ＣＨＫＣＯＩＮ
’－－－　ハンテイヨウニ　サ゛ヒョウヲノコス
ＰＬＸ＝ＰＸ：ＰＬＹ＝ＰＹ：ＲＥＴＵＲＮ

’●ＳＴ＝０（ツウシ゛ョウイト゛ウ
’－－－－－－－－－－－－－－－－－－－－－－－－－－－
＠ＰＷ
ＶＸ＝Ｖ：ＰＸ＝ＰＸ＋ＶＸ＊ＳＰＤ
ＧＯＳＵＢ　＠ＣＨＫＳＤ　：’サユウホセイ
ＧＯＳＵＢ　＠ＣＨＫＦＬ　：’アシモトカクニン
ＩＦ　Ｃ＝＝０　ＴＨＥＮ　＠ＰＦＡＬＬ
’－－－　Аホ゛タンオシタ？
ＩＦ　（ＢＩ　ＡＮＤ　１６）＝＝０　ＴＨＥＮ　ＲＥＴＵＲＮ
’－－－　シ゛ャンフ゜スタ－ト
＠ＰＪＵＭＰ
ＳＴ＝１：ＶＹ＝－４：ＪＣ＝０：ＢＥＥＰ　８
Ｏ（ＩＸ，＿Ｏ）＝ＰＹ　ＡＮＤ　＆Ｈ１Ｆ０
Ｏ（ＩＸ，＿Ｂ）＝ＳＰＣ
ＲＥＴＵＲＮ

’●ＳＴ＝１（シ゛ャンフ゜シ゛ョウショウチュウ
’－－－－－－－－－－－－－－－－－－－－－－－－－－－
＠ＰＪ
ＩＦ　Ｖ！＝０　ＴＨＥＮ　ＶＸ＝Ｖ
ＰＸ＝ＰＸ＋ＶＸ＊ＳＰＤ
ＧＯＳＵＢ　＠ＣＨＫＳＤ　：’サユウホセイ
ＰＹ＝ＰＹ＋ＶＹ
ＧＯＳＵＢ　＠ＣＨＫＨＤ　：’アタマホセイ
ＩＦ　Ｃ！＝０　ＴＨＥＮ　＠ＰＪＨＥＮＤ
’－－－　Аホ゛タンオサレツツ゛ケテル？
ＪＣ＝ＪＣ＋１
ＩＦ　（ＢＴ　ＡＮＤ　１６）＝＝０　ＴＨＥＮ　ＪＣ＝８
ＩＦ　ＪＣ＜８　ＴＨＥＮ　ＲＥＴＵＲＮ
’－－－　ホウフ゛ツセン　カイシ
＠ＰＪＥＮＤ
Ｏ（ＩＸ，＿Ｂ）＝０：ＳＴ＝２：ＲＥＴＵＲＮ
’－－－　シ゛ョウショウチュウ　アタマヲフ゛ツケタ
＠ＰＪＨＥＮＤ
ＩＦ　ＪＣ＝＝０　ＴＨＥＮ　＠ＰＧＬＡＮＤ
ＧＯＴＯ　＠ＰＨＥＮＤ
’－－－　ラッカ　カイシ
＠ＰＦＡＬＬ
Ｃ＝ＢＬＯＣＫ
ＩＦ　ＶＹ＞＝０　ＴＨＥＮ　ＧＯＳＵＢ　＠ＧＥＴＦＬ
Ｏ（ＩＸ，＿Ｂ）＝Ｃ：ＳＴ＝３：ＶＹ＝０：ＲＥＴＵＲＮ

’●ＳＴ＝２（ホウフ゛ツセン→ラッカ
’－－－－－－－－－－－－－－－－－－－－－－－－－－－
＠ＰＨ
ＩＦ　Ｖ！＝０　ＴＨＥＮ　ＶＸ＝Ｖ
ＰＸ＝ＰＸ＋ＶＸ＊ＳＰＤ
ＧＯＳＵＢ　＠ＣＨＫＳＤ　：’サユウホセイ
ＰＹ＝ＰＹ＋ＶＹ：ＶＹ＝ＶＹ＋ＪＶＹ
ＧＯＳＵＢ　＠ＣＨＫＨＤ　：’アタマホセイ
ＩＦ　Ｃ！＝０　ＴＨＥＮ　＠ＰＨＥＮＤ
ＩＦ　ＶＹ＞＝０　ＴＨＥＮ　＠ＰＨＥＮＤ
’－－－　シ゛ョウショウチュウ
ＧＯＳＵＢ　＠ＧＥＴＦＬ
Ｏ（ＩＸ，＿Ｂ）＝Ｃ：ＲＥＴＵＲＮ
’－－－　
＠ＰＨＥＮＤ
ＧＯＳＵＢ　＠ＣＨＫＦＬ　：’アシモトカクニン
ＩＦ　Ｃ＝＝０　ＴＨＥＮ　＠ＰＦＡＬＬ
’－－－　チョクセ゛ンハ　カヘ゛？
ＩＦ　Ｏ（ＩＸ，＿Ｂ）　ＴＨＥＮ　＠ＰＦＡＬＬ
ＧＯＴＯ　＠ＰＧＬＡＮＤ

’●ＳＴ＝３（ラッカ
’－－－－－－－－－－－－－－－－－－－－－－－－－－－
＠ＰＦ
ＩＦ　Ｖ！＝０　ＴＨＥＮ　ＶＸ＝Ｖ：ＧＯＴＯ　＠ＰＦ２
ＶＸ＝ＶＸ＋ＳＧＮ（０－ＶＸ）＊０．０５
＠ＰＦ２
ＰＸ＝ＰＸ＋ＶＸ＊ＳＰＤ
ＧＯＳＵＢ　＠ＣＨＫＳＤ　：’サユウホセイ
ＰＹ＝ＰＹ＋ＶＹ：ＶＹ＝ＶＹ＋ＪＶＹ
ＩＦ　ＶＹ＞４　ＴＨＥＮ　ＶＹ＝４
ＧＯＳＵＢ　＠ＣＨＫＦＬ　：’アシモトカクニン
Ｉ＝Ｏ（ＩＸ，＿Ｂ）：Ｏ（ＩＸ，＿Ｂ）＝Ｃ
ＩＦ　Ｃ＝＝０　ＴＨＥＮ　ＲＥＴＵＲＮ
’－－－　チョクセ゛ンハスヘ゜－ス？
ＩＦ　Ｉ！＝０　ＴＨＥＮ　ＲＥＴＵＲＮ
’－－－　チャクチ＆ホセイ
＠ＰＧＬＡＮＤ
ＶＹ＝０：ＳＴ＝０：Ｏ（ＩＸ，＿Ｂ）＝ＳＰＣ
ＰＹ＝ＰＹ　ＡＮＤ　＆Ｈ１Ｆ０
Ｉ＝Ｏ（ＩＸ，＿Ｏ）：Ｏ（ＩＸ，＿Ｏ）＝ＰＹ
Ｙ＝Ｉ－ＰＹ：ＩＦ　Ｙ＜＝０　ＴＨＥＮ　ＲＥＴＵＲＮ
ＩＦ　Ｉ＞１５９　ＴＨＥＮ　ＲＥＴＵＲＮ
’－－－　スクロ－ルカイシ
Ｉ＝Ｙ　ＡＮＤ　＆Ｈ０Ｆ
ＡＤＤＹ＝Ｙ　ＡＮＤ　＆Ｈ１Ｆ０
ＩＦ　Ｉ　ＴＨＥＮ　ＡＤＤＹ＝ＡＤＤＹ＋１６
ＭＶＹ＝ＭＶＹ＋ＡＤＤＹ
ＲＥＴＵＲＮ

’■ヒョウシ゛ホシ゛ョ
’───────────────────────────
＠ＰＵＴＮ
ＬＯＣＡＴＥ　２５，Ｙ
Ｎ＄＝”　　　　　　　”＋ＳＴＲ＄（Ｎ）
Ｎ＄＝ＭＩＤ＄（Ｎ＄，ＬＥＮ（Ｎ＄）－７，７）
ＰＲＩＮＴ　Ｎ＄：Ｙ＝Ｙ＋３：ＲＥＴＵＲＮ
’－－－
＠ＰＵＴＳＴＡＴ
ＣＯＬＯＲ　０：Ｙ＝２
ＩＦ　ＳＣ＞ＳＣＴＯＰ　ＴＨＥＮ　ＳＣＴＯＰ＝ＳＣ
Ｎ＝ＳＣＴＯＰ：ＧＯＳＵＢ　＠ＰＵＴＮ
Ｎ＝ＳＣ：ＧＯＳＵＢ　＠ＰＵＴＮ
Ｎ＝ＦＬＯＯＲ（ＴＩＭＥ／６０）：ＧＯＳＵＢ　＠ＰＵＴＮ
Ｎ＝ＳＴＧ＋１：ＧＯＳＵＢ　＠ＰＵＴＮ
’－－－
＠ＰＵＴＬＩＦＥ
ＩＦ　ＬＩＦＥ＜０　ＴＨＥＮ　ＲＥＴＵＲＮ
Ｎ＄＝”・・・・・・・ааааааа”
Ｎ＄＝ＭＩＤ＄（Ｎ＄，ＬＩＦＥ，７）
ＬＯＣＡＴＥ　２５，１１：ＣＯＬＯＲ　１３
ＰＲＩＮＴ　Ｎ＄
＠ＰＳＴＥ
ＣＯＬＯＲ　０：ＲＥＴＵＲＮ
’－－－
＠ＭＫＣＯＬ
ＩＦ　Ｃ＞２５５　ＴＨＥＮ　Ｃ＝２５５
Ｃ＄＝”０”＋ＨＥＸ＄（ＦＬＯＯＲ（Ｃ））
Ｃ＄＝ＭＩＤ＄（Ｃ＄，ＬＥＮ（Ｃ＄）－２，２）
ＲＥＴＵＲＮ

’■テ゛－タ
’───────────────────────────
’－－－　マッフ゜１
＠Ｍ１
ＤＡＴＡ　０
ＤＡＴＡ　”□Щ　　　　　　Ц□”
ＤＡＴＡ　”□┏┏┏┏　┏┏┏□”
ＤＡＴＡ　”□　　Ш┏　Ш　　□”
ＤＡＴＡ　”□┏　┏┏┏┏┏┏□”
ＤＡＴＡ　”□Ъ　　　　　　г□”
ＤＡＴＡ　”□□□□□□□□□□”
ＤＡＴＡ　””
’－－－　マッフ゜２
＠Ｍ２
ＤＡＴＡ　２
ＤＡＴＡ　”□Щ　　　Ш　　Ц□”
ＤＡＴＡ　”□┏┏┏┏Ш┏┏┏□”
ＤＡＴＡ　”□　Ц　　Ш　Ш　□”
ＤＡＴＡ　”□┏┏┏┏Ш┏┏　□”
ＤＡＴＡ　”□　┏　　Ш　　　□”
ＤＡＴＡ　”□　┏┏┏┏┏　┏□”
ＤＡＴＡ　”□　ШШШШШ　　□”
ＤＡＴＡ　”□　　　┏　Ц　　□”
ＤＡＴＡ　”□　┏┏┏┏┏Ш┏□”
ＤＡＴＡ　”□　　┏　　ШШШ□”
ＤＡＴＡ　”□　　　Ц　┏Ш　□”
ＤＡＴＡ　”□┏┏┏┏┏┏　┏□”
ＤＡＴＡ　”□　　ШШШ　┏　□”
ＤＡＴＡ　”□　　　　　　┏　□”
ＤＡＴＡ　”□　┏┏┏┏┏　┏□”
ＤＡＴＡ　”□ШШ　　┏　　　□”
ＤＡＴＡ　”□ШШ　┏　　　　□”
ＤＡＴＡ　”□┏┏┏┏┏┏　┏□”
ＤＡＴＡ　”□　　Ш┏Ц　Ё　□”
ＤＡＴＡ　”□　┏┏┏┏┏┏┏□”
ＤＡＴＡ　”□　Ш　Ш┏┏┏　□”
ＤＡＴＡ　”□　　　　　　　　□”
ＤＡＴＡ　”□┏┏┏┏┏┏Ш┏□”
ＤＡＴＡ　”□　　　┏　Ш　　□”
ＤＡＴＡ　”□　Ё　ЦШ　　　□”
ＤＡＴＡ　”□　┏┏┏┏┏　┏□”
ＤＡＴＡ　”□　　　□□　┏　□”
ＤＡＴＡ　”□　Ц　ШШШ　　□”
ＤＡＴＡ　”□┏┏┏┏┏┏Ш┏□”
ＤＡＴＡ　”□　Ш　　　　┏　□”
ＤＡＴＡ　”□　　　ЦШШ　　□”
ＤＡＴＡ　”□┏┏┏┏┏┏　┏□”
ＤＡＴＡ　”□　　Ш　　　Ш　□”
ＤＡＴＡ　”□　Ш　Ш　　┏　□”
ＤＡＴＡ　”□Ш　　　ШЦ　　□”
ＤＡＴＡ　”□　┏┏┏┏┏Ё┏□”
ＤＡＴＡ　”□ШШШШШ　┏　□”
ＤＡＴＡ　”□　　　Ц┏□　　□”
ＤＡＴＡ　”□　　┏┏　　　Ш□”
ＤＡＴＡ　”□ШШШ　г　Ё　□”
ＤＡＴＡ　”□□□□□□□□□□”
ＤＡＴＡ　””
’－－－　マッフ゜３
＠Ｍ３
ＤＡＴＡ　２９
ＤＡＴＡ　”□　　　　　　　　□”
ＤＡＴＡ　”□ЩШШ　г　　Ц□”
ＤＡＴＡ　”□□□□□□□□□□”
ＤＡＴＡ　””
’－－－　マッフ゜ヨミコミ
＠ＳＥＴＭＡＰ
ＭＹ＝０
ＯＮ　ＳＴＧ　ＧＯＴＯ　＠ＳＭ１，＠ＳＭ２，＠ＳＭ３
＠ＳＭ１
ＲＥＳＴＯＲＥ　＠Ｍ１：ＧＯＴＯ　＠ＲＥＡＤＭＡＰ
＠ＳＭ２
ＲＥＳＴＯＲＥ　＠Ｍ２：ＧＯＴＯ　＠ＲＥＡＤＭＡＰ
＠ＳＭ３
ＲＥＳＴＯＲＥ　＠Ｍ３
’－－－
＠ＲＥＡＤＭＡＰ
ＲＥＡＤ　ＭＡＰＢＧＭ
’－－－
＠ＳＥＴＭＬＯＯＰ
ＲＥＡＤ　Ｍ＄（ＭＹ）
ＩＦ　Ｍ＄（ＭＹ）＝＝””　ＴＨＥＮ　ＲＥＴＵＲＮ
ＭＹ＝ＭＹ＋１
ＧＯＴＯ　＠ＳＥＴＭＬＯＯＰ

’－－－　ＢＧカヘ゛フ゛ヒンヨミコミ
＠ＷＡＬＬ
’０：スヘ゜－ス
ＤＡＴＡ　７１７，１５，７１７，１５
ＤＡＴＡ　７１７，１５，７１７，１５
’１：В
ＤＡＴＡ　９０８，１２，９０９，１２
ＤＡＴＡ　９４０，１２，９４１，１２
’２：□
ＤＡＴＡ　７２１，１０，７２２，１０
ＤＡＴＡ　７５３，１０，７５４，１０
’３：┏
ＤＡＴＡ　　４５，　９，　４７，　９
ＤＡＴＡ　７１７，１１，７１７，１１
’４：Т
ＤＡＴＡ　９２９，１５，９２９，１５
ＤＡＴＡ　９２９，１５，９２９，１５
’５：エラ－ヨウ
ＤＡＴＡ　７１７，　０，７１７，　０
ＤＡＴＡ　７１７，　０，７１７，　０
’６：Ё　カイフク
ＤＡＴＡ　　　４，　０，　　５，　０
ＤＡＴＡ　　　６，　０，　　７，　０
’７：◎　コイン
ＤＡＴＡ　　　８，　０，　　９，　０
ＤＡＴＡ　　１０，　０，　１１，　０
’８：
ＤＡＴＡ　　　０，　０，　　０，　０
ＤＡＴＡ　　　０，　０，　　０，　０
’－－－
＠ＳＥＴＷＡＬＬ
ＲＥＳＴＯＲＥ　＠ＷＡＬＬ
ＦＯＲ　Ｉ＝０　ＴＯ　ＷＡＬＬＭＡＸ－１
　ＦＯＲ　Ｊ＝０　ＴＯ　ＷＡＬＬＳＴ－１
　　ＲＥＡＤ　Ｗ（Ｉ，Ｊ）
　ＮＥＸＴ
ＮＥＸＴ
ＲＥＴＵＲＮ

’■ＢＧホシ゛ョ
’───────────────────────────

’－－－　ＢＧハンテイ
＠ＣＨＫＨＤ
Ｘ＝（ＰＸ／８）　ＡＮＤ　３１
Ｙ＝（（ＰＹ＋ＭＯＹ－１６）／８）　ＡＮＤ　６３
ＢＧＲＥＡＤ（１，Ｘ，Ｙ），Ｃ，Ｐ，Ｗ，Ｈ
ＩＦ　Ｃ＜４８　ＴＨＥＮ　Ｃ＝０：ＲＥＴＵＲＮ
ＩＦ　Ｃ＝＝ＳＰＣ　ＴＨＥＮ　Ｃ＝０：ＲＥＴＵＲＮ
ＰＹ＝（ＰＹ　ＡＮＤ　＆ＨＦ０）＋１６
ＲＥＴＵＲＮ
’－－－
＠ＣＨＫＦＬ
Ｘ＝（ＰＸ／８）　ＡＮＤ　３１
Ｙ＝（（ＰＹ＋ＭＯＹ）／８）　ＡＮＤ　６３
ＢＧＲＥＡＤ（１，Ｘ，Ｙ），Ｃ，Ｐ，Ｗ，Ｈ
ＩＦ　Ｃ！＝ＳＰＣ　ＴＨＥＮ　ＲＥＴＵＲＮ
Ｃ＝０：ＲＥＴＵＲＮ

’－－－
＠ＣＨＫＣＯＩＮ
Ｘ＝（（ＰＸ／１６）　ＡＮＤ　１５）＊２
Ｙ＝（（（ＰＹ＋ＭＯＹ－８）／１６）　ＡＮＤ　３１）＊２
ＢＧＲＥＡＤ（０，Ｘ，Ｙ），Ｃ，Ｐ，Ｗ，Ｈ
ＩＦ　Ｃ＜４　ＴＨＥＮ　ＲＥＴＵＲＮ
ＩＦ　Ｃ＜８　ＴＨＥＮ　＠ＬＩＦＥＵＰ
ＳＣ＝ＳＣ＋１０：ＢＥＥＰ　７
ＧＯＳＵＢ　＠ＣＬＲＷＡＬＬ：ＧＯＴＯ　＠ＰＵＴＳＴＡＴ
＠ＬＩＦＥＵＰ
ＬＩＦＥ＝ＬＩＦＥ＋１：ＢＥＥＰ　５
ＧＯＳＵＢ　＠ＣＬＲＷＡＬＬ：ＧＯＴＯ　＠ＰＵＴＳＴＡＴ

’－－－
＠ＧＥＴＦＬ
Ｘ＝（ＰＸ／８）　ＡＮＤ　３１
Ｙ＝（（ＰＹ＋ＭＯＹ）／８）　ＡＮＤ　６３
ＢＧＲＥＡＤ（１，Ｘ，Ｙ），Ｃ，Ｐ，Ｗ，Ｈ
ＩＦ　Ｃ＝＝ＳＰＣ　ＴＨＥＮ　Ｃ＝０
ＲＥＴＵＲＮ

’－－－
＠ＣＨＫＳＤ
Ｘ＝（ＰＸ／８）　ＡＮＤ　３１
Ｙ＝（（ＰＹ＋ＭＯＹ－１６）／８）　ＡＮＤ　６３
ＢＧＲＥＡＤ（１，Ｘ，Ｙ），Ｃ，Ｐ，Ｗ，Ｈ
ＩＦ　Ｃ＝＝ＳＰＣ　ＴＨＥＮ　Ｃ＝０：ＲＥＴＵＲＮ
ＩＦ　Ｃ＜４８　ＴＨＥＮ　Ｃ＝０：ＲＥＴＵＲＮ
’－－－
＠ＣＳ１
ＩＦ　Ｃ＝＝７２１　ＴＨＥＮ　＠ＣＳＬ
ＩＦ　Ｃ！＝７５３　ＴＨＥＮ　＠ＣＳ２
＠ＣＳＬ
ＰＸ＝Ｘ＊８－１：ＲＥＴＵＲＮ
’－－－
＠ＣＳ２
ＩＦ　Ｃ＝＝７２２　ＴＨＥＮ　＠ＣＳＲ
ＩＦ　Ｃ！＝７５４　ＴＨＥＮ　Ｃ＝０：ＲＥＴＵＲＮ
＠ＣＳＲ
ＰＸ＝Ｘ＊８＋８：ＲＥＴＵＲＮ

’－－－　ＢＧショウキョ
＠ＢＧＣＬＲ
ＦＯＲ　Ｐ＝０　ＴＯ　１
　ＦＯＲ　Ｙ＝０　ＴＯ　６３
　　ＦＯＲ　Ｘ＝０　ＴＯ　６３
　　　ＢＧＰＵＴ　Ｐ，Ｘ，Ｙ，０，０，０，０
　　ＮＥＸＴ
　ＮＥＸＴ
ＮＥＸＴ
ＲＥＴＵＲＮ

’－－－　ＢＧスクロ－ル
＠ＢＧＳＣＲＬ
ＩＦ　ＭＶＹ＜＝０　ＴＨＥＮ　ＯＶＹ＝０：ＲＥＴＵＲＮ
Ｉ＝ＭＯＹ　ＡＮＤ　１５
ＩＦ　Ｉ＝＝０　ＴＨＥＮ　ＧＯＳＵＢ　＠ＰＵＴＬＩＮＥ
ＯＶＹ＝２
ＭＶＹ＝ＭＶＹ－ＯＶＹ：ＭＯＹ＝ＭＯＹ－ＯＶＹ
ＢＧＯＦＳ　０，０，ＭＯＹ
ＢＧＯＦＳ　１，０，ＭＯＹ
ＲＥＴＵＲＮ

’－－－　スフ゜ライトキャラヲＢＧヘ　テンソウ
＠ＣＨＲＣＯＰＹ
Ｎ＝６０＊４：Ｂ＝４：ＧＯＳＵＢ　＠ＣＣＰＳＵＢ
Ｎ＝３６＊４：Ｂ＝８
＠ＣＣＰＳＵＢ
ＦＯＲ　Ｉ＝０　ＴＯ　３
　ＣＨＲＲＥＡＤ（”ＳＰＵ０”，Ｎ＋Ｉ），Ｃ＄
　ＣＨＲＳＥＴ　”ＢＧＵ０”，Ｂ＋Ｉ，Ｃ＄
ＮＥＸＴ
ＲＥＴＵＲＮ

’■マッフ゜ホシ゛ョ
’───────────────────────────

’－－－　ＢＧ２ｘ２ヒョウシ゛
＠ＰＵＴＷＡＬＬ　’Ｄ＄，Ｘ，Ｙ
Ｂ＝０
ＩＦ　Ｗ＄＝＝”Ё”　ＴＨＥＮ　Ｉ＝６：ＧＯＴＯ　＠ＰＦＲ
ＩＦ　Ｗ＄＝＝”Ш”　ＴＨＥＮ　Ｉ＝７：ＧＯＴＯ　＠ＰＦＲ
Ｂ＝１
ＩＦ　Ｗ＄＝＝”В”　ＴＨＥＮ　Ｉ＝１：ＧＯＴＯ　＠ＰＷＰ
ＩＦ　Ｗ＄＝＝”□”　ＴＨＥＮ　Ｉ＝２：ＧＯＴＯ　＠ＰＷＰ
ＩＦ　Ｗ＄＝＝”┏”　ＴＨＥＮ　Ｉ＝３：ＧＯＴＯ　＠ＰＷＰ
ＩＦ　Ｗ＄＝＝”Т”　ＴＨＥＮ　Ｉ＝４：ＧＯＴＯ　＠ＰＷＰ
ＩＦ　Ｗ＄＝＝”　”　ＴＨＥＮ　Ｉ＝０：ＧＯＴＯ　＠ＰＷＰ
’－－－　フ゜レイヤ－？
Ｉ＝０：Ｎ＝２５２：Ｔ＝１：Ｃ＝４
ＩＦ　Ｗ＄＝＝”г”　ＴＨＥＮ　＠ＰＷＯＳＥＴ
’－－－　アキヲサカ゛ス
Ｎ＝１２８：Ｔ＝２：Ｃ＝２
＠ＷＯＬＰ
ＩＦ　Ｏ（Ｉ，＿Ｔ）＝＝０　ＴＨＥＮ　＠ＰＷＯＳＥＴ
Ｉ＝Ｉ＋１：ＩＦ　Ｉ＜ＯＢＪＭＡＸ　ＴＨＥＮ　＠ＷＯＬＰ
’－－－　アキカ゛ナイノテ゛エラ－アツカイ
Ｉ＝５：ＧＯＴＯ　＠ＰＷＰ

’－－－　オフ゛シ゛ェクト　シンキトウロク
＠ＰＷＯＳＥＴ
ＯＢＪ＝ＯＢＪ＋１：Ｏ（Ｉ，＿Ｘ）＝Ｘ＊８＋８
Ｏ（Ｉ，＿Ｙ）＝Ｙ＊８＋１６－ＭＯＹ
ＩＦ　Ｗ＄！＝”Щ”　ＴＨＥＮ　＠ＰＷＯＡＮＭ
Ｎ＝５９：Ｔ＝３：Ｃ＝１
ＳＰＣＨＲ　Ｉ，Ｎ，３，０，０，ＰＲ
’－－－
＠ＰＷＯＡＮＭ
Ｏ（Ｉ，＿Ｔ）＝Ｔ：Ｏ（Ｉ，＿Ｎ）＝Ｎ
Ｏ（Ｉ，＿Ｓ）＝０：Ｏ（Ｉ，＿Ｗ）＝０：Ｏ（Ｉ，＿Ｈ）＝０
ＳＰＡＮＩＭ　Ｉ，Ｃ，８，０
ＳＰＣＨＲ　Ｉ，Ｎ，０，０，０，ＰＲ
ＳＰＯＦＳ　Ｉ，Ｏ（Ｉ，＿Ｘ）－８，Ｏ（Ｉ，＿Ｙ）－１６
Ｉ＝０：ＧＯＴＯ　＠ＰＷＰ

’－－－　オモテケス
＠ＣＬＲＷＡＬＬ
Ｂ＝０：Ｉ＝８
ＧＯＴＯ　＠ＰＷＰ

’－－－　オモテ２カイカク
＠ＰＦＲ
ＧＯＳＵＢ　＠ＰＷＰ
Ｂ＝１：Ｉ＝０

’－－－　２ｘ２ヒョウシ゛
＠ＰＷＰ
Ｊ＝Ｙ　ＡＮＤ　６３
Ｎ＝Ｗ（Ｉ，０）：Ｃ＝Ｗ（Ｉ，１）
ＢＧＰＵＴ　Ｂ，Ｘ，Ｊ，Ｎ，Ｃ，０，０
Ｎ＝Ｗ（Ｉ，２）：Ｃ＝Ｗ（Ｉ，３）
ＢＧＰＵＴ　Ｂ，Ｘ＋１，Ｊ，Ｎ，Ｃ，０，０
Ｎ＝Ｗ（Ｉ，４）：Ｃ＝Ｗ（Ｉ，５）
Ｊ＝（Ｊ＋１）　ＡＮＤ　６３
ＢＧＰＵＴ　Ｂ，Ｘ，Ｊ，Ｎ，Ｃ，０，０
Ｎ＝Ｗ（Ｉ，６）：Ｃ＝Ｗ（Ｉ，７）
ＢＧＰＵＴ　Ｂ，Ｘ＋１，Ｊ，Ｎ，Ｃ，０，０
ＲＥＴＵＲＮ

’－－－　マッフ゜１キ゛ョウヒョウシ゛
＠ＰＵＴＬＩＮＥ　’ＭＰＹ
Ｙ＝２２－（ＭＰＹ＊２）：Ｘ＝４
Ｊ＝（Ｙ＋１）　ＡＮＤ　６３
ＦＯＲ　Ｉ＝４　ＴＯ　２３
　ＢＧＰＵＴ　０，Ｉ，Ｙ，０，０，０，０
　ＢＧＰＵＴ　０，Ｉ，Ｊ，０，０，０，０
ＮＥＸＴ
’－－－
Ｄ＄＝”ТТТТТТТТТТ”
ＩＦ　ＭＰＹ＞ＭＹ＋２　ＴＨＥＮ　＠ＰＬＯＦＦ
Ｄ＄＝”□　　　　　　　　□”
ＩＦ　ＭＰＹ＞＝ＭＹ　ＴＨＥＮ　＠ＰＬＯＦＦ
Ｄ＄＝Ｍ＄（ＭＹ－１－ＭＰＹ）
’－－－
＠ＰＬＯＦＦ
ＦＯＲ　ＩＭ＝０　ＴＯ　９
　Ｗ＄＝ＭＩＤ＄（Ｄ＄，ＩＭ，１）
　ＧＯＳＵＢ　＠ＰＵＴＷＡＬＬ
　Ｘ＝Ｘ＋２
ＮＥＸＴ
ＭＰＹ＝ＭＰＹ＋１
ＲＥＴＵＲＮ

’■オフ゛シ゛ェクトホシ゛ョ
’───────────────────────────
＠ＯＢＪＩＮＩＴ
ＦＯＲ　Ｉ＝０　ＴＯ　ＯＢＪＭＡＸ－１
　ＦＯＲ　Ｊ＝０　ＴＯ　＿ＭＡＸ－１
　　Ｏ（Ｉ，Ｊ）＝０
　ＮＥＸＴ
　ＳＰＳＥＴ　Ｉ，１２８＋Ｉ，２，０，０，ＰＲ
　ＳＰＯＦＳ　Ｉ，－１６，０
ＮＥＸＴ
’－－－　フ゜レイヤ－
ＳＰＳＥＴ　０，０，２，０，０，２
ＳＰＯＦＳ　０，－１６，０
Ｏ（０，＿Ｔ）＝１
’－－－　ト゛クケムリ
ＦＯＲ　Ｉ＝０　ＴＯ　１５
　Ｎ＝Ｉ＋８４
　ＳＰＳＥＴ　Ｎ，２４０，５，０，０，０
　ＳＰＯＦＳ　Ｎ，Ｉ＊１６，１８０
　ＳＰＡＮＩＭ　Ｎ，８，４，０
ＮＥＸＴ
ＲＥＴＵＲＮ