STAR BATTLER by もりちゃん
２画面を使った、２人対戦のシューティングゲームの登場だ。
下画面タッチでゲームスタート（または終了）。タイトル画面に表示されている通り、前後左右とショットでそれぞれのプレイヤー機を操作する。一方向に押せば押すほどスピードが上がっていき、逆方向に押せば減速する、無重力の操作感にまず慣れておこう。
相手と撃ち合って画面上部のダメージ率を100％にするのが目的だが、ときどき現われるスターを取るとある程度回復になる。
ほかにもアイテムは、弾を画面内に何発まで撃てるか（赤色ゲージ）を変える「Ｒ」、敵に与えるダメージ量（黄色ゲージ）を変える「Ｐ」がある。アイテムが緑色ならゲージ上昇だが、赤色だとかえって低下してしまうので要注意。
私が作りました
もりちゃん
シューティングゲームを作っていたら、いつの間にか対戦ゲームになっていました。
De・バグ コーナー
（6月30日）下記のように訂正してください
491行目 LOCATE 21,21:PRINT "† FIRE";
（†＝Ｒボタン記号）
CHECK POiNT 
ウォオー！ 右手と……左手が……あっちとこっちで……グァアー！ シィィット！
ワンパク君、２人用ゲームを１人で遊ぶのは無理がないかい。まあ、こういう遊び方もあるといえばあるかな。
確かに、２人用だというだけでスルーするのはもったいない本格派じゃな。
ワシも拡大文字の処理にはビックリじゃ。手製の
ワシも拡大文字の処理にはビックリじゃ。手製の
ＧＰＵＴＣＨＲ拡張命令といったところかの。ラベル名が＠ＳＹＭＢＯＬというのはF-BASIC使いならニヤリとするところじゃろう。
BGを使った２重スクロールや、その下のグラフィック面で書いた流れ星みたいな細かい演出も雰囲気があっていいね。
そのへんのルーチンはラベルが始まってから
ＲＥＴＵＲＮで終わるまで全部カラにして打っても動作に問題ないんだぜ！ 打ち込むにはてっとり早えんじゃねェか？ワンパク君が言うとハラハラするが、手軽に打ち込んでゲームを楽しんだり、ゲーム本体やルーチンごとに解析したりするにはそれもひとつの手段じゃな。ワシとしてはそれぞれの処理を楽しみながら打つのも一興じゃが。
プログラムリスト
- ’┌────────────┐
- ’│ＳＴＡＲ ＢＡＴＴＬＥＲ│
- ’└────────────┘
- ’ショキセッテイ
- ＶＩＳＩＢＬＥ １，１，０，０，１，１
- ＣＯＬＯＲ １５：ＣＬＳ：ＢＧＭＳＴＯＰ
- ＦＯＲ Ｐ＝０ ＴＯ １
- ＧＰＡＧＥ Ｐ：ＳＰＰＡＧＥ Ｐ：ＢＧＰＡＧＥ Ｐ
- ＦＯＲ Ｉ＝０ ＴＯ ２５５
- ＣＯＬＩＮＩＴ ”ＧＲＰ”，Ｉ
- ＣＯＬＩＮＩＴ ”ＢＧ”，Ｉ
- ＮＥＸＴ Ｉ
- ＧＣＯＬＯＲ ０：ＧＣＬＳ：ＳＰＣＬＲ
- ＢＧＣＬＩＰ ０，０，３１，２３
- ＢＧＯＦＳ ０，０，０：ＢＧＯＦＳ １，０，０
- ＮＥＸＴ Ｐ
- ＧＰＡＧＥ ０：ＳＰＰＡＧＥ ０：ＢＧＰＡＧＥ ０
- ＰＮＬＴＹＰＥ ”ＯＦＦ”
- ＣＬＥＡＲ：ＸＹＭＡＸ＝１６：ＮＮ＝１０
- ＤＩＭ Ｂ１（２，４），ＢＣＮＴ（２，４）
- ＤＩＭ ＸＢ（２，４），ＹＢ（２，４），ＹＳ（２）
- ＤＩＭ Ａ１（２），ＸＸ（２），ＹＹ（２），ＲＥＮ（２）
- ＤＩＭ ＤＭ（２），ＰＷ（２），ＲＦ（２），ＴＡ（２）
- ＤＩＭ Ｃ＄（３，２５６），ＫＥＹＮＯ（２，５）
- ＤＩＭ ＸＮ（ＮＮ），ＹＮ（ＮＮ），ＣＮ（ＮＮ）
- ’キ－Ｎｏ．トウロク
- ＦＯＲ Ｉ＝０ ＴＯ １
- ＦＯＲ Ｊ＝０ ＴＯ ４
- ＲＥＡＤ ＮＯ
- ＫＥＹＮＯ（Ｉ，Ｊ）＝ＮＯ
- ＮＥＸＴ Ｊ
- ＮＥＸＴ Ｉ
- ＤＡＴＡ １， ２， ４， ８，２５６
- ＤＡＴＡ ６４， ３２，１２８， １６，５１２
- ’ＢＧ（ホシソ゛ラ）セッテイ
- Ｃ＄＝”００００００００”
- Ｃ＄＝Ｃ＄＋Ｃ＄＋Ｃ＄＋Ｃ＄＋Ｃ＄＋Ｃ＄＋Ｃ＄＋Ｃ＄
- ＦＯＲ Ｉ＝０ ＴＯ ２
- ＦＯＲ Ｊ＝０ ＴＯ ２５５
- Ｃ＄（Ｉ，Ｊ）＝Ｃ＄
- ＮＥＸＴ Ｊ
- ＮＥＸＴ Ｉ
- ＦＯＲ Ｉ＝１ ＴＯ ２００
- Ｃ１＝ＲＮＤ（３） ：Ｃ２＝ＲＮＤ（２５６）
- Ｃ３＝ＲＮＤ（６４）：Ｃ４＝ＲＮＤ（１６）
- ＣＢ＄＝Ｃ＄（Ｃ１，Ｃ２）
- Ｃ＄（Ｃ１，Ｃ２）＝ＭＩＤ＄（ＣＢ＄，０，Ｃ３）＋ＨＥＸ＄（Ｃ４）＋ＭＩＤ＄（ＣＢ＄，Ｃ３＋１，６３－Ｃ３）
- ＮＥＸＴ Ｉ
- ＦＯＲ Ｐ＝０ ＴＯ １
- ＢＧＰＡＧＥ Ｐ
- ＦＯＲ Ｉ＝０ ＴＯ ２
- Ｉ＄＝”ＢＧＵ”＋ＳＴＲ＄（Ｉ）
- ＦＯＲ Ｊ＝０ ＴＯ ２５５
- ＣＨＲＳＥＴ Ｉ＄，Ｊ，Ｃ＄（Ｉ，Ｊ）
- ＮＥＸＴ Ｊ
- ＮＥＸＴ Ｉ
- ＦＯＲ Ｉ＝０ ＴＯ ４７
- ＦＯＲ Ｊ＝０ ＴＯ ３１
- ＢＧＰＵＴ ０， Ｊ， Ｉ，（Ｉ ％ ２４）＊３２＋Ｊ，０，０，０
- ＢＧＰＵＴ １，３１－Ｊ，４７－Ｉ，（Ｉ ％ ２４）＊３２＋Ｊ，０，０，０
- ＮＥＸＴ Ｊ
- ＮＥＸＴ Ｉ
- ＮＥＸＴ Ｐ
- ＦＯＲ Ｉ＝０ ＴＯ ＮＮ－１
- ＸＮ（Ｉ）＝－１
- ＮＥＸＴ Ｉ
- ’スフ゜ライトセッテイ
- ’０－３：シ゛キ ４－７：タマ ８－１１：ハ゛クハツ
- ’１２：ハ゜ワ－アッフ゜ １３：レンシャアッフ゜
- ’１４：ハ゜ワ－タ゛ウン １５：レンシャタ゛ウン
- ’１６－１９：ライフアッフ゜
- ＣＨＲＩＮＩＴ ”ＳＰＵ０”
- ＣＨＲＩＮＩＴ ”ＳＰＵ２”
- ＣＨＲＩＮＩＴ ”ＳＰＵ３”
- ＦＯＲ Ｉ＝０ ＴＯ １９
- ＲＥＡＤ ＮＯ１，ＮＯ２
- ＦＯＲ Ｊ＝０ ＴＯ ３
- ＳＰＰＡＧＥ ０
- ＣＨＲＲＥＡＤ（”ＳＰＵ”＋ＳＴＲ＄（ＮＯ１），ＮＯ２＊４＋Ｊ），Ｓ＄
- ＣＨＲＳＥＴ ”ＳＰＵ０”，Ｉ＊４＋Ｊ，Ｓ＄
- ＳＰＰＡＧＥ １
- ＣＨＲＳＥＴ ”ＳＰＳ０”，Ｉ＊４＋Ｊ，Ｓ＄
- ＮＥＸＴ Ｊ
- ＮＥＸＴ Ｉ
- ＤＡＴＡ ２， ８，２， ９，２，１０，２，１１
- ＤＡＴＡ ０，４０，０，４２，０，４４，０，４６
- ＤＡＴＡ ３，５６，３，５７，３，５８，３，５９
- ＤＡＴＡ ３，４１，３，４３，３，４０，３，４２
- ＤＡＴＡ ２，２８，２，２９，２，３０，２，３１
- ’［Ｂ］→［Ｒ］ヘンカン
- ＦＯＲ Ｉ＝０ ＴＯ ２ ＳＴＥＰ ２
- ＳＰＰＡＧＥ ０
- ＣＨＲＲＥＡＤ（”ＳＰＵ０”，（１３＋Ｉ）＊４＋３），Ｓ＄
- ＳＲ＄＝ＭＩＤ＄（Ｓ＄，０，１６）
- ＳＲ＄＝ＳＲ＄＋ＭＩＤ＄（Ｓ＄，８，３）
- ＳＲ＄＝ＳＲ＄＋ＭＩＤ＄（Ｓ＄，１９，６４－１９）
- ＣＨＲＳＥＴ ”ＳＰＵ０”，（１３＋Ｉ）＊４＋３，ＳＲ＄
- ＳＰＰＡＧＥ １
- ＣＨＲＳＥＴ ”ＳＰＳ０”，（１３＋Ｉ）＊４＋３，ＳＲ＄
- ＮＥＸＴ Ｉ
- ＦＯＲ Ｐ＝０ ＴＯ １
- ＳＰＰＡＧＥ Ｐ
- ＦＯＲ Ｉ＝０ ＴＯ ３
- ＳＰＳＥＴ Ｉ ，０，０，０，０，０
- ＳＰＯＦＳ Ｉ ，－１６，－１６
- ＳＰＳＥＴ Ｉ＋１０，０，２，０，０，０
- ＳＰＯＦＳ Ｉ＋１０，－１６，－１６
- ＳＰＳＥＴ Ｉ＋３０，０，２，０，０，０
- ＳＰＯＦＳ Ｉ＋３０，－１６，－１６
- ＳＰＳＥＴ Ｉ＋４０，０，０，０，０，０
- ＳＰＯＦＳ Ｉ＋４０，－１６，－１６
- ＮＥＸＴ Ｉ
- ＳＰＳＥＴ ５０，１２，４，０，０，０
- ＳＰＯＦＳ ５０，－１６，－１６
- ＳＰＳＥＴ ５１，１３，４，０，０，０
- ＳＰＯＦＳ ５１，－１６，－１６
- ＳＰＳＥＴ ５２，１４，２，０，０，０
- ＳＰＯＦＳ ５２，－１６，－１６
- ＳＰＳＥＴ ５３，１５，２，０，０，０
- ＳＰＯＦＳ ５３，－１６，－１６
- ＳＰＳＥＴ ５４，１６，３，０，０，０
- ＳＰＯＦＳ ５４，－１６，－１６
- ＳＰＡＮＩＭ ５４，４，１０，０
- ＮＥＸＴ Ｐ
- ＠ＳＴＡＲＴ
- ＧＯＳＵＢ ＠ＴＩＴＬＥ
- ＩＦ ＥＤ ＴＨＥＮ ＶＩＳＩＢＬＥ １，１，０，０，１，１：ＥＮＤ
- ’シ゛ョウタイクリア
- ＳＰＰＡＧＥ ０
- ＦＯＲ Ｉ＝０ ＴＯ １
- Ｘ（Ｉ）＝２０＋Ｉ＊２００：Ｙ（Ｉ）＝２０＋Ｉ＊３３０
- Ａ１（Ｉ）＝Ｉ＊２＋１：ＲＥＮ（Ｉ）＝０：ＴＡ（Ｉ）＝０
- ＤＭ（Ｉ）＝０：ＰＷ（Ｉ）＝２：ＲＦ（Ｉ）＝２
- ＸＸ（Ｉ）＝０：ＹＹ（Ｉ）＝０：ＹＳ（Ｉ）＝０
- ＦＯＲ Ｊ＝０ ＴＯ ３
- Ｂ１（Ｉ，Ｊ）＝０：ＢＣＮＴ（Ｉ，Ｊ）＝０
- ＮＥＸＴ Ｊ
- ＳＰＰＡＧＥ （Ｙ（Ｉ）＞１９１）
- ＳＰＣＨＲ Ｉ＊３０，Ａ１（Ｉ）
- ＳＰＯＦＳ Ｉ＊３０，Ｘ（Ｉ），Ｙ（Ｉ）
- ＮＥＸＴ Ｉ
- ＢＫＣＮＴ＝０：ＢＫ＝－１：ＹＩＤ＝０
- ＧＯＳＵＢ ＠ＩＮＦＯ
- ’メインル－チン
- ＠ＭＡＩＮ
- ＢＴＮ＝０：Ｍ＝０
- ＦＯＲ Ｉ＝０ ＴＯ ４
- ＶＳＹＮＣ １
- ＢＴＮ１＝ＢＵＴＴＯＮ（）
- ＩＦ ＢＴＮ１ ＴＨＥＮ ＢＴＮ＝ＢＴＮ１
- ＦＯＲ Ｊ＝０ ＴＯ １
- ＩＦ （ＢＴＮ ＡＮＤ ＫＥＹＮＯ（Ｊ，４））＝＝０ ＴＨＥＮ ＲＥＮ（Ｊ）＝０
- ＮＥＸＴ Ｊ
- ＮＥＸＴ Ｉ
- ＠ＬＯＯＰ
- ＭＡ＝Ｍ＊３０：ＭＢ＝ＭＡ＋１０
- ＩＦ ＢＫＣＮＴ＞０ ＡＮＤ Ｍ＝＝ＢＫ ＴＨＥＮ ＢＫＣＮＴ＝ＢＫＣＮＴ＋１：ＧＯＴＯ ＠ＬＮＥＸＴ１
- ＩＦ ＢＴＮ ＡＮＤ ＫＥＹＮＯ（Ｍ，０） ＴＨＥＮ ＹＹ（Ｍ）＝ＹＹ（Ｍ）－２：Ａ１（Ｍ）＝３
- ＩＦ ＢＴＮ ＡＮＤ ＫＥＹＮＯ（Ｍ，１） ＴＨＥＮ ＹＹ（Ｍ）＝ＹＹ（Ｍ）＋２：Ａ１（Ｍ）＝１
- ＩＦ ＢＴＮ ＡＮＤ ＫＥＹＮＯ（Ｍ，２） ＴＨＥＮ ＸＸ（Ｍ）＝ＸＸ（Ｍ）－２：Ａ１（Ｍ）＝２
- ＩＦ ＢＴＮ ＡＮＤ ＫＥＹＮＯ（Ｍ，３） ＴＨＥＮ ＸＸ（Ｍ）＝ＸＸ（Ｍ）＋２：Ａ１（Ｍ）＝０
- ＩＦ ＸＸ（Ｍ）＜－ＸＹＭＡＸ ＴＨＥＮ ＸＸ（Ｍ）＝－ＸＹＭＡＸ
- ＩＦ ＸＸ（Ｍ）＞ ＸＹＭＡＸ ＴＨＥＮ ＸＸ（Ｍ）＝ ＸＹＭＡＸ
- ＩＦ ＹＹ（Ｍ）＜－ＸＹＭＡＸ ＴＨＥＮ ＹＹ（Ｍ）＝－ＸＹＭＡＸ
- ＩＦ ＹＹ（Ｍ）＞ ＸＹＭＡＸ ＴＨＥＮ ＹＹ（Ｍ）＝ ＸＹＭＡＸ
- Ｘ（Ｍ）＝Ｘ（Ｍ）＋ＸＸ（Ｍ）：Ｙ（Ｍ）＝Ｙ（Ｍ）＋ＹＹ（Ｍ）
- ＩＦ Ｘ（Ｍ）＜＝－１６ ＴＨＥＮ Ｘ（Ｍ）＝Ｘ（Ｍ）＋２５６
- ＩＦ Ｘ（Ｍ）＞＝２５６ ＴＨＥＮ Ｘ（Ｍ）＝Ｘ（Ｍ）－２５６
- ＩＦ Ｙ（Ｍ）＜＝－１６ ＴＨＥＮ Ｙ（Ｍ）＝Ｙ（Ｍ）＋３８４
- ＩＦ Ｙ（Ｍ）＞＝３８４ ＴＨＥＮ Ｙ（Ｍ）＝Ｙ（Ｍ）－３８４
- ＰＧ＝（Ｙ（Ｍ）＞１９１）
- Ｙ２＝Ｙ（Ｍ）－１９２＊ＰＧ
- ＳＰＰＡＧＥ ＰＧ
- ＳＰＣＨＲ ＭＡ，Ａ１（Ｍ）
- ＳＰＯＦＳ ＭＡ，Ｘ（Ｍ），Ｙ２
- ＳＰＰＡＧＥ １－ＰＧ
- ＳＰＯＦＳ ＭＡ，－１６，－１６
- ＸＡ＝０：ＹＡ＝０
- ＩＦ Ｘ（Ｍ）＜０ ＴＨＥＮ ＸＡ＝ ２５６
- ＩＦ Ｘ（Ｍ）＞２３９ ＴＨＥＮ ＸＡ＝－２５６
- ＩＦ Ｙ（Ｍ）＜０ ＴＨＥＮ ＹＡ＝ １９２
- ＩＦ Ｙ（Ｍ）＞３６７ ＴＨＥＮ ＹＡ＝－１９２
- ＩＦ Ｙ（Ｍ）＞１７５ ＡＮＤ Ｙ（Ｍ）＜１９２ ＴＨＥＮ ＹＡ＝－１９２
- ＦＯＲ Ｐ＝０ ＴＯ １
- ＳＰＰＡＧＥ Ｐ
- ＳＰＯＦＳ ＭＡ＋１，－１６，－１６：ＳＰＯＦＳ ＭＡ＋２，－１６，－１６：ＳＰＯＦＳ ＭＡ＋３，－１６，－１６
- ＮＥＸＴ Ｐ
- ＳＰＰＡＧＥ ＰＧ
- ＩＦ ＸＡ ＴＨＥＮ ＳＰＣＨＲ ＭＡ＋１，Ａ１（Ｍ）：ＳＰＯＦＳ ＭＡ＋１，Ｘ（Ｍ）＋ＸＡ，Ｙ２
- ＳＰＰＡＧＥ １－ＰＧ
- ＩＦ ＹＡ ＴＨＥＮ ＳＰＣＨＲ ＭＡ＋２，Ａ１（Ｍ）：ＳＰＯＦＳ ＭＡ＋２，Ｘ（Ｍ） ，Ｙ２＋ＹＡ
- ＩＦ ＸＡ ＡＮＤ ＹＡ ＴＨＥＮ ＳＰＣＨＲ ＭＡ＋３，Ａ１（Ｍ）：ＳＰＯＦＳ ＭＡ＋３，Ｘ（Ｍ）＋ＸＡ，Ｙ２＋ＹＡ
- ＩＦ ＢＴＮ ＡＮＤ ＫＥＹＮＯ（Ｍ，４） ＴＨＥＮ Ｉ＝０：ＧＯＳＵＢ ＠ＦＩＲＥ
- ＸＣ＝Ｘ（１－Ｍ）：ＹＣ＝Ｙ（１－Ｍ）
- ＩＦ ＸＣ＜８ ＴＨＥＮ ＸＣ＝ＸＣ＋２５６
- ＩＦ ＹＣ＜８ ＴＨＥＮ ＹＣ＝ＹＣ＋３８４
- ＠ＬＮＥＸＴ１
- ＦＯＲ Ｉ＝０ ＴＯ ３
- ＩＦ ＢＣＮＴ（Ｍ，Ｉ）＞０ ＴＨＥＮ ＧＯＳＵＢ ＠ＴＡＭＡ
- ＮＥＸＴ Ｉ
- ＩＦ Ｍ＝＝０ ＴＨＥＮ Ｍ＝１：ＧＯＴＯ ＠ＬＯＯＰ
- ＩＦ ＹＩＤ＝＝０ ＡＮＤ ＲＮＤ（３０）＝＝０ ＴＨＥＮ ＧＯＳＵＢ ＠ＩＴＥＭＳＥＴ
- ＩＦ ＹＩＤ ＴＨＥＮ ＧＯＳＵＢ ＠ＩＴＥＭＳＣＲ
- ＩＦ ＢＫＣＮＴ＝＝０ ＴＨＥＮ ＢＥＥＰ ２１，（ＡＢＳ（ＸＸ（０））＋ＡＢＳ（ＹＹ（０））＋ＡＢＳ（ＹＹ（１）））＊１２５
- ＧＯＳＵＢ ＠ＳＣＲＯＬＬ
- ＧＯＳＵＢ ＠ＳＨＯＯＴＩＮＧ
- ＩＦ ＢＫＣＮＴ＞＝４０ ＴＨＥＮ ＠ＧＡＭＥＯＶＥＲ
- ＧＯＴＯ ＠ＭＡＩＮ
- ’ホシソ゛ラスクロ－ル
- ＠ＳＣＲＯＬＬ
- ＦＯＲ Ｐ＝０ ＴＯ １
- ＢＧＰＡＧＥ Ｐ
- ＦＯＲ Ｉ＝０ ＴＯ １
- ＹＳ（Ｉ）＝ＹＳ（Ｉ）＋Ｉ＋１
- ＩＦ ＹＳ（Ｉ）＞１９１ ＴＨＥＮ ＹＳ（Ｉ）＝０
- ＢＧＯＦＳ Ｉ，０，ＹＳ（Ｉ）
- ＮＥＸＴ Ｉ
- ＮＥＸＴ Ｐ
- ＲＥＴＵＲＮ
- ’ナカ゛レホ゛シ
- ＠ＳＨＯＯＴＩＮＧ
- ＦＯＲ Ｉ＝０ ＴＯ ＮＮ－１
- ＩＦ ＸＮ（Ｉ）＜０ ＴＨＥＮ ＠ＳＨＴＮＥＸＴ１
- ＧＰ＝（ＹＮ（Ｉ）＞１９１）
- ＧＰＡＧＥ ＧＰ
- ＧＬＩＮＥ ＸＮ（Ｉ），ＹＮ（Ｉ）－１９２＊ＧＰ，ＸＮ（Ｉ）＋３，ＹＮ（Ｉ）－３－１９２＊ＧＰ，０
- ＸＮ（Ｉ）＝ＸＮ（Ｉ）－４：ＹＮ（Ｉ）＝ＹＮ（Ｉ）＋４
- ＩＦ ＸＮ（Ｉ）＜０ ＯＲ ＹＮ（Ｉ）＞３８３ ＴＨＥＮ ＸＮ（Ｉ）＝－１：ＧＯＴＯ ＠ＳＨＴＮＥＸＴ１
- ＧＰ＝（ＹＮ（Ｉ）＞１９１）
- ＧＰＡＧＥ ＧＰ
- ＧＬＩＮＥ ＸＮ（Ｉ），ＹＮ（Ｉ）－１９２＊ＧＰ，ＸＮ（Ｉ）＋３，ＹＮ（Ｉ）－３－１９２＊ＧＰ，ＣＮ（Ｉ）
- ＠ＳＨＴＮＥＸＴ１
- ＮＥＸＴ Ｉ
- ＠ＳＨＴＳＥＴ
- ＦＯＲ Ｉ＝０ ＴＯ ＮＮ－１
- ＩＦ ＸＮ（Ｉ）＞＝０ ＴＨＥＮ ＠ＳＨＴＮＥＸＴ２
- ＸＮ（Ｉ）＝ＲＮＤ（２５６）
- ＹＮ（Ｉ）＝ＲＮＤ（９４）＊４＋８
- ＣＮ（Ｉ）＝ＲＮＤ（２５５）＋１
- Ｉ＝ＮＮ
- ＠ＳＨＴＮＥＸＴ２
- ＮＥＸＴ Ｉ
- ＲＥＴＵＲＮ
- ’タマハッシャ
- ＠ＦＩＲＥ
- ＩＦ ＲＥＮ（Ｍ） ＯＲ ＴＡ（Ｍ）＞＝ＲＦ（Ｍ） ＴＨＥＮ ＲＥＴＵＲＮ
- ＩＦ ＢＣＮＴ（Ｍ，Ｉ）＜＝０ ＴＨＥＮ ＠ＦＩＲＥＳＥＴ
- Ｉ＝Ｉ＋１
- ＧＯＴＯ ＠ＦＩＲＥ
- ＠ＦＩＲＥＳＥＴ
- Ｂ１（Ｍ，Ｉ）＝Ａ１（Ｍ）：ＸＢ（Ｍ，Ｉ）＝Ｘ（Ｍ）：ＹＢ（Ｍ，Ｉ）＝Ｙ（Ｍ）
- ＢＣＮＴ（Ｍ，Ｉ）＝１０：ＲＥＮ（Ｍ）＝１：ＴＡ（Ｍ）＝ＴＡ（Ｍ）＋１
- ＰＧ＝（ＹＢ（Ｍ，Ｉ）＞１９１）
- ＳＰＰＡＧＥ ＰＧ
- ＳＰＣＨＲ ＭＢ＋Ｉ，Ｂ１（Ｍ，Ｉ）＋４
- ＳＰＯＦＳ ＭＢ＋Ｉ，ＸＢ（Ｍ，Ｉ），ＹＢ（Ｍ，Ｉ）－１９２＊ＰＧ
- ＩＦ ＢＫＣＮＴ＝＝０ ＴＨＥＮ ＢＥＥＰ １０，Ｍ＊２０００
- ＲＥＴＵＲＮ
- ’タマイト゛ウ
- ＠ＴＡＭＡ
- ＩＦ Ｂ１（Ｍ，Ｉ）＝＝０ ＴＨＥＮ ＸＢ（Ｍ，Ｉ）＝ＸＢ（Ｍ，Ｉ）＋１６
- ＩＦ Ｂ１（Ｍ，Ｉ）＝＝１ ＴＨＥＮ ＹＢ（Ｍ，Ｉ）＝ＹＢ（Ｍ，Ｉ）＋１６
- ＩＦ Ｂ１（Ｍ，Ｉ）＝＝２ ＴＨＥＮ ＸＢ（Ｍ，Ｉ）＝ＸＢ（Ｍ，Ｉ）－１６
- ＩＦ Ｂ１（Ｍ，Ｉ）＝＝３ ＴＨＥＮ ＹＢ（Ｍ，Ｉ）＝ＹＢ（Ｍ，Ｉ）－１６
- ＩＦ ＸＢ（Ｍ，Ｉ）＜＝ －８ ＴＨＥＮ ＸＢ（Ｍ，Ｉ）＝ＸＢ（Ｍ，Ｉ）＋２５６
- ＩＦ ＸＢ（Ｍ，Ｉ）＞＝２４８ ＴＨＥＮ ＸＢ（Ｍ，Ｉ）＝ＸＢ（Ｍ，Ｉ）－２５６
- ＩＦ ＹＢ（Ｍ，Ｉ）＜＝ －８ ＴＨＥＮ ＹＢ（Ｍ，Ｉ）＝ＹＢ（Ｍ，Ｉ）＋３８４
- ＩＦ ＹＢ（Ｍ，Ｉ）＞＝３７６ ＴＨＥＮ ＹＢ（Ｍ，Ｉ）＝ＹＢ（Ｍ，Ｉ）－３８４
- ＰＧ＝（ＹＢ（Ｍ，Ｉ）＞１９１）
- ＳＰＰＡＧＥ ＰＧ
- ＳＰＣＨＲ ＭＢ＋Ｉ，Ｂ１（Ｍ，Ｉ）＋４
- ＳＰＯＦＳ ＭＢ＋Ｉ，ＸＢ（Ｍ，Ｉ），ＹＢ（Ｍ，Ｉ）－１９２＊ＰＧ
- ＳＰＰＡＧＥ １－ＰＧ
- ＳＰＯＦＳ ＭＢ＋Ｉ，－１６，－１６
- ＧＯＳＵＢ ＠ＣＨＥＣＫ
- ＢＣＮＴ（Ｍ，Ｉ）＝ＢＣＮＴ（Ｍ，Ｉ）－１
- ＩＦ ＣＫ ＴＨＥＮ ＢＣＮＴ（Ｍ，Ｉ）＝０
- ＩＦ ＢＣＮＴ（Ｍ，Ｉ）＜＝０ ＴＨＥＮ ＳＰＰＡＧＥ ＰＧ：ＳＰＯＦＳ ＭＢ＋Ｉ，－１６，－１６：ＴＡ（Ｍ）＝ＴＡ（Ｍ）－１
- ＩＦ ＣＫ ＴＨＥＮ ＧＯＳＵＢ ＠ＤＡＭＡＧＥ
- ＲＥＴＵＲＮ
- ’アタリハンテイ
- ＠ＣＨＥＣＫ
- ＣＫ＝０
- ＩＦ ＢＫＣＮＴ＞０ ＴＨＥＮ ＲＥＴＵＲＮ
- ＸＺ＝ＡＢＳ（Ｘ（１－Ｍ）－ＸＢ（Ｍ，Ｉ））
- ＹＺ＝ＡＢＳ（Ｙ（１－Ｍ）－ＹＢ（Ｍ，Ｉ））
- ＩＦ （ＸＺ＜＝８ ＯＲ ＸＺ＞＝２４８）ＡＮＤ ＹＺ＜＝８ ＯＲ ＹＺ＞＝３７６ ＴＨＥＮ ＣＫ＝１
- ＲＥＴＵＲＮ
- ’タ゛メ－シ゛
- ＠ＤＡＭＡＧＥ
- ＤＭ（１－Ｍ）＝ＤＭ（１－Ｍ）＋ＰＷ（Ｍ）＊５＋５
- ＩＦ ＤＭ（１－Ｍ）＞１００ ＴＨＥＮ ＤＭ（１－Ｍ）＝１００
- ＧＯＳＵＢ ＠ＩＮＦＯ
- ＩＦ ＤＭ（１－Ｍ）＞＝１００ ＴＨＥＮ ＧＯＳＵＢ ＠ＢＡＫＵＨＡＴＵ：ＲＥＴＵＲＮ
- ＢＥＥＰ １１，（１－Ｍ）＊２０００
- ＲＥＴＵＲＮ
- ’アイテムセット
- ＠ＩＴＥＭＳＥＴ
- ＸＩ＝ＲＮＤ（２４０）：ＹＩＤ＝ＲＮＤ（２）＊２－１
- ＹＩ＝－ＹＩＤ＊２００＋１８４：ＩＴ＝ＲＮＤ（５）
- ＩＦ ＢＫＣＮＴ＝＝０ ＴＨＥＮ ＢＥＥＰ １２
- ＲＥＴＵＲＮ
- ’アイテムスクロ－ル
- ＠ＩＴＥＭＳＣＲ
- ＹＩ＝ＹＩ＋ＹＩＤ＊４
- ＳＰＰＡＧＥ ０：ＳＰＯＦＳ ＩＴ＋５０，ＸＩ，ＹＩ
- ＳＰＰＡＧＥ １：ＳＰＯＦＳ ＩＴ＋５０，ＸＩ，ＹＩ－１９２
- ＩＦ ＹＩ＜－１５ ＯＲ ＹＩ＞３８３ ＴＨＥＮ ＹＩＤ＝０：ＲＥＴＵＲＮ
- ＧＯＳＵＢ ＠ＩＴＥＭＣＨＫ
- ＩＦ ＣＫ＜０ ＴＨＥＮ ＲＥＴＵＲＮ
- ＢＰ＝０
- ＯＮ ＩＴ ＧＯＳＵＢ ＠ＰＯＷＥＲＵＰ，＠ＲＡＰＩＤＵＰ，＠ＰＯＷＥＲＤＮ，＠ＲＡＰＩＤＤＮ，＠ＬＩＦＥＵＰ
- ＦＯＲ Ｐ＝０ ＴＯ １
- ＳＰＰＡＧＥ Ｐ：ＳＰＯＦＳ ＩＴ＋５０，－１６，－１６
- ＮＥＸＴ Ｐ
- ＧＯＳＵＢ ＠ＩＮＦＯ
- ＩＦ ＢＫＣＮＴ＝＝０ ＴＨＥＮ ＢＥＥＰ ＢＰ，ＣＫ＊２０００
- ＹＩＤ＝０
- ＲＥＴＵＲＮ
- ’ハ゜ワ－アッフ゜
- ＠ＰＯＷＥＲＵＰ
- ＢＰ＝８：ＰＷ（ＣＫ）＝ＰＷ（ＣＫ）＋１
- ＩＦ ＰＷ（ＣＫ）＞４ ＴＨＥＮ ＰＷ（ＣＫ）＝４
- ＲＥＴＵＲＮ
- ’レンシャアッフ゜
- ＠ＲＡＰＩＤＵＰ
- ＢＰ＝８：ＲＦ（ＣＫ）＝ＲＦ（ＣＫ）＋１
- ＩＦ ＲＦ（ＣＫ）＞４ ＴＨＥＮ ＲＦ（ＣＫ）＝４
- ＲＥＴＵＲＮ
- ’ハ゜ワ－タ゛ウン
- ＠ＰＯＷＥＲＤＮ
- ＢＰ＝４：ＰＷ（ＣＫ）＝ＰＷ（ＣＫ）－１
- ＩＦ ＰＷ（ＣＫ）＜１ ＴＨＥＮ ＰＷ（ＣＫ）＝１
- ＲＥＴＵＲＮ
- ’レンシャタ゛ウン
- ＠ＲＡＰＩＤＤＮ
- ＢＰ＝４：ＲＦ（ＣＫ）＝ＲＦ（ＣＫ）－１
- ＩＦ ＲＦ（ＣＫ）＜１ ＴＨＥＮ ＲＦ（ＣＫ）＝１
- ＲＥＴＵＲＮ
- ’ライフアッフ゜
- ＠ＬＩＦＥＵＰ
- ＢＰ＝３２：ＤＭ（ＣＫ）＝ＤＭ（ＣＫ）－２０
- ＩＦ ＤＭ（ＣＫ）＜０ ＴＨＥＮ ＤＭ（ＣＫ）＝０
- ＲＥＴＵＲＮ
- ’アイテムケ゛ットチェック
- ＠ＩＴＥＭＣＨＫ
- ＣＫ＝－１
- ＦＯＲ Ｉ＝０ ＴＯ １
- ＸＺ＝ＡＢＳ（Ｘ（Ｉ）－ＸＩ）
- ＹＺ＝ＡＢＳ（Ｙ（Ｉ）－ＹＩ）
- ＩＦ （ＸＺ＜＝８ ＯＲ ＸＺ＞＝２４８） ＡＮＤ ＹＺ＜＝８ ＯＲ ＹＺ＞＝３７６ ＴＨＥＮ ＣＫ＝Ｉ：Ｉ＝１
- ＮＥＸＴ Ｉ
- ＲＥＴＵＲＮ
- ’シ゛ョウホウヒョウシ゛
- ＠ＩＮＦＯ
- ＧＰＡＧＥ ０
- ＦＯＲ Ｉ＝０ ＴＯ １
- ＣＯＬＯＲ Ｉ＊２＋１１：ＬＯＣＡＴＥ Ｉ＊１４＋５，０
- ＰＲＩＮＴ ” ”；
- ＬＯＣＡＴＥ Ｉ＊１４＋８－ＬＥＮ（ＳＴＲ＄（ＤＭ（Ｉ））），０
- ＰＲＩＮＴ ＤＭ（Ｉ）；”％”；
- ＦＯＲ Ｊ＝０ ＴＯ ３
- ＸＧ＝Ｉ＊１１２＋Ｊ＊８
- ＧＢＯＸ ＸＧ＋７２，１，ＸＧ＋７７，２，２＊（ＰＷ（Ｉ）＞Ｊ）
- ＧＢＯＸ ＸＧ＋７２，４，ＸＧ＋７７，５，１２＊（ＲＦ（Ｉ）＞Ｊ）
- ＮＥＸＴ Ｊ
- ＮＥＸＴ Ｉ
- ＲＥＴＵＲＮ
- ’ハ゛クハツ
- ＠ＢＡＫＵＨＡＴＵ
- ＢＫＣＮＴ＝１：ＢＫ＝１－Ｍ：ＭＡ＝ＢＫ＊３０
- ＦＯＲ Ｐ＝０ ＴＯ １
- ＳＰＰＡＧＥ Ｐ
- ＦＯＲ Ｊ＝０ ＴＯ ３
- ＳＰＣＨＲ ＭＡ＋Ｊ，８
- ＳＰＡＮＩＭ ＭＡ＋Ｊ，４，１０，０
- ＮＥＸＴ Ｊ
- ＮＥＸＴ Ｐ
- ＢＥＥＰ １３，ＢＫ＊２０００
- ＲＥＴＵＲＮ
- ’ケ゛－ムオ－ハ゛－
- ＠ＧＡＭＥＯＶＥＲ
- ＢＧＭＰＬＡＹ ６：＿Ｍ＝８：＿Ｏ＝＆Ｈ１０：＿Ｙ＝６４
- ＦＯＲ Ｉ＝１ ＴＯ ２２
- ＧＰＡＧＥ ０：ＧＣＯＬＯＲ ０：ＧＣＬＳ
- ＿Ｚ＄＝ＳＴＲ＄（２－ＢＫ）
- ＿Ｘ＝２５６－Ｉ＊３２＋６＊６４
- ＧＣＯＬＯＲ ＢＫ＊２＋２
- ＧＯＳＵＢ ＠ＳＹＭＢＯＬ
- ＦＯＲ Ｊ＝０ ＴＯ ５
- ＧＰＵＴＣＨＲ ２５６－Ｉ＊３２＋Ｊ＊６４，６４，”ＢＧＦ０”，ＡＳＣ（ＭＩＤ＄（”ＰＬＡＹＥＲ”，Ｊ，１）），１３－ＢＫ＊２，８
- ＮＥＸＴ Ｊ
- ＧＰＡＧＥ １：ＧＣＯＬＯＲ ０：ＧＣＬＳ
- ＦＯＲ Ｊ＝０ ＴＯ ４
- ＧＰＵＴＣＨＲ ２５６－Ｉ＊３２＋（Ｊ＋２）＊６４，６４，”ＢＧＦ０”，ＡＳＣ（ＭＩＤ＄（”ＷＩＮ！！”，Ｊ，１）），４，８
- ＮＥＸＴ Ｊ
- ＶＳＹＮＣ １１
- ＮＥＸＴ Ｉ
- ＠ＯＶＥＲＷＡＩＴ
- ＩＦ ＢＧＭＣＨＫ（）＝＝ＴＲＵＥ ＴＨＥＮ ＠ＯＶＥＲＷＡＩＴ
- ＦＯＲ Ｐ＝０ ＴＯ １
- ＧＰＡＧＥ Ｐ：ＧＣＯＬＯＲ ０：ＣＬＳ
- ＳＰＰＡＧＥ Ｐ
- ＦＯＲ Ｉ＝０ ＴＯ １
- ＳＰＯＦＳ ＩＴ＋５０，－１６，－１６
- ＦＯＲ Ｊ＝０ ＴＯ ３
- ＳＰＡＮＩＭ Ｉ＊３０＋Ｊ，１，０，０
- ＳＰＯＦＳ Ｉ＊３０＋Ｊ，－１６，－１６
- ＳＰＯＦＳ Ｉ＊３０＋Ｊ＋１０，－１６，－１６
- ＮＥＸＴ Ｊ
- ＮＥＸＴ Ｉ
- ＮＥＸＴ Ｐ
- ＧＯＴＯ ＠ＳＴＡＲＴ
- ’タイトル
- ＠ＴＩＴＬＥ
- ＶＩＳＩＢＬＥ １，１，０，０，１，０
- ＣＬＳ：ＧＰＡＧＥ ０
- ＿Ｍ＝６：＿Ｏ＝＆Ｈ００：＿Ｚ＄＝”ＳＴＡＲ”
- ＦＯＲ Ｉ＝５ ＴＯ １ ＳＴＥＰ －１
- ＧＣＯＬＯＲ ＆Ｈ３Ｅ－Ｉ
- ＿Ｘ＝Ｉ＊４－６：＿Ｙ＝Ｉ＊２
- ＧＯＳＵＢ ＠ＳＹＭＢＯＬ
- ＮＥＸＴ Ｉ
- ＧＣＯＬＯＲ １１
- ＿Ｘ＝－６：＿Ｙ＝０
- ＧＯＳＵＢ ＠ＳＹＭＢＯＬ
- ＿Ｍ＝４：＿Ｚ＄＝”ＢＡＴＴＬＥＲ”
- ＦＯＲ Ｉ＝５ ＴＯ １ ＳＴＥＰ －１
- ＧＣＯＬＯＲ ＆ＨＥ５＋Ｉ
- ＿Ｘ＝Ｉ＊４＋１８：＿Ｙ＝Ｉ＊２＋４８
- ＧＯＳＵＢ ＠ＳＹＭＢＯＬ
- ＮＥＸＴ Ｉ
- ＧＣＯＬＯＲ １２
- ＿Ｘ＝１８：＿Ｙ＝４８
- ＧＯＳＵＢ ＠ＳＹＭＢＯＬ
- ＧＰＡＧＥ １
- ＸＴ１＝８：ＸＴ２＝１３６：ＹＴ＝１０４
- ＸＴＷ＝１１１：ＹＴＷ＝７９
- ＧＦＩＬＬ ＸＴ１，ＹＴ，ＸＴ１＋ＸＴＷ，ＹＴ＋ＹＴＷ，４
- ＧＢＯＸ ＸＴ１，ＹＴ，ＸＴ１＋ＸＴＷ，ＹＴ＋ＹＴＷ，１５
- ＧＦＩＬＬ ＸＴ２，ＹＴ，ＸＴ２＋ＸＴＷ，ＹＴ＋ＹＴＷ，２
- ＧＢＯＸ ＸＴ２，ＹＴ，ＸＴ２＋ＸＴＷ，ＹＴ＋ＹＴＷ，１５
- ＧＣＯＬＯＲ １５
- ＿Ｘ＝２４：＿Ｙ＝１３６：＿Ｍ＝２：＿Ｚ＄＝”ＳＴＡＲＴ”
- ＧＯＳＵＢ ＠ＳＹＭＢＯＬ
- ＿Ｘ＝１６８：＿Ｚ＄＝”ＥＮＤ”
- ＧＯＳＵＢ ＠ＳＹＭＢＯＬ
- ＣＯＬＯＲ １５
- ＬＯＣＡＴＥ ５，１３：ＰＲＩＮＴ ”ＰＬＡＹＥＲ １”；
- ＬＯＣＡＴＥ ８，１５：ＰＲＩＮＴ ”↑”；
- ＬＯＣＡＴＥ ５，１７：ＰＲＩＮＴ ”←”；
- ＬＯＣＡＴＥ １１，１７：ＰＲＩＮＴ ”→”；
- ＬＯＣＡＴＥ ８，１９：ＰＲＩＮＴ ”↓”；
- ＬＯＣＡＴＥ ６，２１：ＰＲＩＮＴ ”К ＦＩＲＥ”；
- ＬＯＣＡＴＥ ２０，１３：ＰＲＩＮＴ ”ＰＬＡＹＥＲ ２”；
- ＬＯＣＡＴＥ ２３，１５：ＰＲＩＮＴ ”Ф”；
- ＬＯＣＡＴＥ ２０，１７：ＰＲＩＮＴ ”Х”；
- ＬＯＣＡＴＥ ２６，１７：ＰＲＩＮＴ ”А”；
- ＬＯＣＡＴＥ ２３，１９：ＰＲＩＮＴ ”Б”；
- ＬＯＣＡＴＥ ２１，２１：ＰＲＩＮＴ ”н ＦＩＲＥ”；
- ＳＰＰＡＧＥ ０
- ＳＰＣＨＲ ０，３：ＳＰＯＦＳ ０，６０，１３２
- ＳＰＣＨＲ ３０，３：ＳＰＯＦＳ ３０，１８０，１３２
- ＰＮＬＳＴＲ ５，３，”ＰＯＷＥＲ ＵＰ” ，１５
- ＰＮＬＳＴＲ ５，９，”ＲＡＰＩＤ ＵＰ” ，１５
- ＰＮＬＳＴＲ ２０，３，”ＰＯＷＥＲ ＤＯＷＮ”，１５
- ＰＮＬＳＴＲ ２０，９，”ＲＡＰＩＤ ＤＯＷＮ”，１５
- ＰＮＬＳＴＲ １３，６，”ＬＩＦＥ ＵＰ” ，１５
- ＳＰＰＡＧＥ １
- ＳＰＯＦＳ ５０， ２０，２０
- ＳＰＯＦＳ ５１， ２０，６８
- ＳＰＯＦＳ ５２，１４０，２０
- ＳＰＯＦＳ ５３，１４０，６８
- ＳＰＯＦＳ ５４， ８４，４４
- ＶＩＳＩＢＬＥ １，１，１，１，１，１
- ＢＧＭＰＬＡＹ １５：ＥＤ＝０
- ＠ＴＣＨＷＡＩＴ
- ＧＯＳＵＢ ＠ＳＣＲＯＬＬ
- ＶＳＹＮＣ ４
- ＩＦ ＴＣＨＳＴ＝＝ＦＡＬＳＥ ＴＨＥＮ ＠ＴＣＨＷＡＩＴ
- ＸＴ０＝ＴＣＨＸ：ＹＴ０＝ＴＣＨＹ
- ＩＦ ＸＴ０＜ＸＴ１ ＯＲ ＸＴ０＞ＸＴ２＋ＸＴＷ ＯＲ ＹＴ０＜ＹＴ ＯＲ ＹＴ０＞ＹＴ＋ＹＴＷ ＴＨＥＮ ＠ＴＣＨＷＡＩＴ
- ＩＦ ＸＴ０＞ＸＴ１＋ＸＴＷ ＡＮＤ ＸＴ０＜ＸＴ２ ＴＨＥＮ ＠ＴＣＨＷＡＩＴ
- ＩＦ ＸＴ０＞＝ＸＴ２ ＴＨＥＮ ＥＤ＝１
- ＦＯＲ Ｐ＝０ ＴＯ １
- ＧＰＡＧＥ Ｐ：ＧＣＯＬＯＲ ０：ＧＣＬＳ
- ＮＥＸＴ Ｐ
- ＦＯＲ Ｉ＝０ ＴＯ ４
- ＳＰＯＦＳ Ｉ＋５０，－１６，－１６
- ＮＥＸＴ Ｉ
- ＳＰＰＡＧＥ ０
- ＳＰＯＦＳ ０，－１６，－１６
- ＳＰＯＦＳ ３０，－１６，－１６
- ＣＬＳ：ＢＧＭＳＴＯＰ
- ＲＥＴＵＲＮ
- ’モシ゛カクタ゛イ
- ＠ＳＹＭＢＯＬ
- ＿Ｏ１＝（＿Ｏ ＡＮＤ ＆Ｈ０Ｆ）
- ＿Ｏ２＝（＿Ｏ ＡＮＤ ＆ＨＦ０）
- ＩＦ ＿Ｏ１＝＝０ ＴＨＥＮ ＿Ｘ１＝＿Ｘ：＿Ｙ１＝＿Ｙ
- ＿ＬＥＮ＝ＬＥＮ（＿Ｚ＄）
- ＦＯＲ ＿Ｉ＝０ ＴＯ ＿ＬＥＮ－１
- ＣＨＲＲＥＡＤ（”ＢＧＦ０”，ＡＳＣ（ＭＩＤ＄（＿Ｚ＄，＿Ｉ，１））），＿Ｃ＄
- ＦＯＲ ＿Ｊ＝０ ＴＯ ７
- ＿Ｙ２＝＿Ｙ１＋＿Ｍ－１
- ＦＯＲ ＿Ｋ＝０ ＴＯ ７
- ＿Ｘ２＝＿Ｘ１＋＿Ｍ－１
- ＿Ａ＄＝ＭＩＤ＄（＿Ｃ＄，＿Ｊ＊８＋＿Ｋ，１）
- ＩＦ ＿Ａ＄＝＝”０” ＴＨＥＮ ＠＿ＮＥＸＴ４
- ＩＦ ＿Ｏ＝＝０ ＴＨＥＮ ＧＦＩＬＬ ＿Ｘ１，＿Ｙ１，＿Ｘ２，＿Ｙ２：ＧＯＴＯ ＠＿ＮＥＸＴ４
- ＧＰＳＥＴ ＿Ｘ１，＿Ｙ１：ＧＰＳＥＴ ＿Ｘ１，＿Ｙ２
- ＧＰＳＥＴ ＿Ｘ２，＿Ｙ１：ＧＰＳＥＴ ＿Ｘ２，＿Ｙ２
- ＩＦ ＿Ｊ！＝０ ＴＨＥＮ ＩＦ ＭＩＤ＄（＿Ｃ＄，（＿Ｊ－１）＊８＋＿Ｋ，１）！＝”０” ＴＨＥＮ ＠＿ＮＥＸＴ１
- ＧＬＩＮＥ ＿Ｘ１，＿Ｙ１，＿Ｘ２，＿Ｙ１
- ＠＿ＮＥＸＴ１
- ＩＦ ＿Ｊ！＝７ ＴＨＥＮ ＩＦ ＭＩＤ＄（＿Ｃ＄，（＿Ｊ＋１）＊８＋＿Ｋ，１）！＝”０” ＴＨＥＮ ＠＿ＮＥＸＴ２
- ＧＬＩＮＥ ＿Ｘ１，＿Ｙ２，＿Ｘ２，＿Ｙ２
- ＠＿ＮＥＸＴ２
- ＩＦ ＿Ｋ！＝０ ＴＨＥＮ ＩＦ ＭＩＤ＄（＿Ｃ＄，＿Ｊ＊８＋（＿Ｋ－１），１）！＝”０” ＴＨＥＮ ＠＿ＮＥＸＴ３
- ＧＬＩＮＥ ＿Ｘ１，＿Ｙ１，＿Ｘ１，＿Ｙ２
- ＠＿ＮＥＸＴ３
- ＩＦ ＿Ｋ！＝７ ＴＨＥＮ ＩＦ ＭＩＤ＄（＿Ｃ＄，＿Ｊ＊８＋（＿Ｋ＋１），１）！＝”０” ＴＨＥＮ ＠＿ＮＥＸＴ４
- ＧＬＩＮＥ ＿Ｘ２，＿Ｙ１，＿Ｘ２，＿Ｙ２
- ＠＿ＮＥＸＴ４
- ＿Ｘ１＝＿Ｘ１＋＿Ｍ
- ＮＥＸＴ ＿Ｋ
- ＿Ｘ１＝＿Ｘ１－＿Ｍ＊８：＿Ｙ１＝＿Ｙ１＋＿Ｍ
- ＮＥＸＴ ＿Ｊ
- ＿Ｘ１＝＿Ｘ１＋＿Ｍ＊８：＿Ｙ１＝＿Ｙ１－＿Ｍ＊８
- ＮＥＸＴ ＿Ｉ
- ＲＥＴＵＲＮ
