プチコン：プログラムリスト

スマイルブーム自家製プログラム特集 PART6 →PART7

FUDO3 by スマイルブーム

　「FUDO3」……すなわち「不動産」がテーマのゲームだ。
　すべきことは、自分（赤）のサイコロを振ることだけ。進んだ先に買い手のない土地（白）があれば、自動的に自分のサイフ（ステータスパネル内の数字）から支払われてその土地が自分のものになる。進んだ先が敵プレイヤーの買った土地（青・オレンジ・緑）だと、その土地に設定された値段だけ相手に支払うことになってしまうぞ。
　画面の上1/3は遠景で見たマップの様子。画面中央は拡大図で、十字ボタン左右で遠景→拡大図の表示位置をスクロールさせることができる。
　最初は原野と更地しかないマップだが、買い手がつくと商店やスーパーに変わって価格も高くなる。さらに買い手が赤字にならないうちに自分の土地に止まれば、より高いマンション、オフィスにと進化するぞ。

CHECK POiNT

全体マップとクローズアップ画面を使った、定番のスゴロク不動産ゲームだね。

なるほど、スゴロク不動産ゲーム……それはわかるぜ。だが……そのワリに面白い気がしねえのは、なぜだ？　シット！

なるほどサイコロを振るだけではゲーム性に欠ける、というコトがよくわかるのう。

土地を買うか買わないか、増額するかやめるか、そういった判断をプレイヤーの選択肢に加えるとゲーム性が高くなるだろうね。

ガッデム！　なんとなくワカってきたぜ！　このヤロー基礎工事だけやって満足しきりやがったなアァ！　ファッキンシット！

ま、まあまあ。ホラ、終了条件とか、メッセージの表示とか、簡単な改造で面白くできるポイントがたくさん残ってるいう考え方もあるよ！

テ、テメエ……ゼエ、ゼエ……いいかげんツッコむのも疲れてきたぜ……オレが間違ってるのか……？

プログラムリスト


’┌──────────┐
’│フト゛ウサンケ゛－ム│
’└──────────┘
ＣＬＥＡＲ
’０
ＤＡＴＡ　”▲”
ＤＡＴＡ　”　　　　　”
ＤＡＴＡ　”　　　　　”
ＤＡＴＡ　”　　　　　”
ＤＡＴＡ　”　　　　　”
ＤＡＴＡ　”┨┓┠┷┓”
ＤＡＴＡ　”┷┷┷┷┷”
ＤＡＴＡ　”┴┴┴┴┴”
ＤＡＴＡ　”ケ゛ンヤ　”
’１
ＤＡＴＡ　”．”
ＤＡＴＡ　”　　　　　”
ＤＡＴＡ　”　　　　　”
ＤＡＴＡ　”　　　　　”
ＤＡＴＡ　”　　　　　”
ＤＡＴＡ　”　　　　　”
ＤＡＴＡ　”　┷　┷　”
ＤＡＴＡ　”─┴─┴─”
ＤＡＴＡ　”サラチ　　”
’２
ＤＡＴＡ　”Ч”
ＤＡＴＡ　”　　　　　”
ＤＡＴＡ　”　　　　　”
ＤＡＴＡ　”　　　　　”
ＤＡＴＡ　”　　　　　”
ＤＡＴＡ　”　┝┿┰　”
ＤＡＴＡ　”　│○│　”
ＤＡＴＡ　”─┴─┴─”
ＤＡＴＡ　”ショウテン”
’３
ＤＡＴＡ　”┠”
ＤＡＴＡ　”　　　　　”
ＤＡＴＡ　”　　　　　”
ＤＡＴＡ　”　　　　　”
ＤＡＴＡ　”　　　　　”
ＤＡＴＡ　”┌───┐”
ＤＡＴＡ　”│□□□│”
ＤＡＴＡ　”┴───┴”
ＤＡＴＡ　”ス－ハ゜－”
’４
ＤＡＴＡ　”┷”
ＤＡＴＡ　”　　　　　”
ＤＡＴＡ　”　　　　　”
ＤＡＴＡ　”┌───┐”
ＤＡＴＡ　”│□□□│”
ＤＡＴＡ　”├───┤”
ＤＡＴＡ　”│□□□│”
ＤＡＴＡ　”┴───┴”
ＤＡＴＡ　”マンション”
’５
ＤＡＴＡ　”■”
ＤＡＴＡ　”┌───┐”
ＤＡＴＡ　”│□□□│”
ＤＡＴＡ　”├───┤”
ＤＡＴＡ　”│□□□│”
ＤＡＴＡ　”├───┤”
ＤＡＴＡ　”│□□□│”
ＤＡＴＡ　”┴───┴”
ＤＡＴＡ　”オフィス　”
’６
ＤＡＴＡ　”＄”
ＤＡＴＡ　”　　　　　”
ＤＡＴＡ　”　ＧＥＴ　”
ＤＡＴＡ　”　┌─┐　”
ＤＡＴＡ　”　│＄│　”
ＤＡＴＡ　”　└─┘　”
ＤＡＴＡ　”ＭＯＮＥＹ”
ＤＡＴＡ　”─────”
ＤＡＴＡ　”ВВВВВ”
’－－－
ＴＭＡＸ＝７
ＤＩＭ　Ｂ＄（ＴＭＡＸ，９）
ＦＯＲ　Ｉ＝０　ＴＯ　ＴＭＡＸ－１
　ＦＯＲ　Ｊ＝０　ＴＯ　８
　　ＲＥＡＤ　Ｂ＄（Ｉ，Ｊ）
　ＮＥＸＴ
ＮＥＸＴ
’－－－
ＤＩＭ　Ｃ（６）
Ｃ（０）＝０：Ｃ（１）＝１２：Ｃ（２）＝９
Ｃ（３）＝７：Ｃ（４）＝４：Ｃ（５）＝３
’－－－
ＤＩＭ　Ｎ＄（４）
Ｎ＄（０）＝”アナタ　”
Ｎ＄（１）＝”タナカ　”
Ｎ＄（２）＝”スス゛キ”
Ｎ＄（３）＝”ヤマタ゛”
’－－－
ＤＩＭ　Ｕ（４，２）
ＦＯＲ　Ｉ＝０　ＴＯ　３
　Ｕ（Ｉ，０）＝５００
　Ｕ（Ｉ，１）＝０
ＮＥＸＴ
’－－－
ＭＭＡＸ＝３２
ＤＩＭ　Ｍ（ＭＭＡＸ，８）
＿Ｂ＝０：＿Ｍ＝１：＿Ｕ＝２：’＿＿＿＿＿

’－－－
ＦＬ＝－１：ＲＱ＝１

’┌───┐
’│メイン│
’└───┘
＠ＬＯＯＰ
　ＯＬＤＢ＝Ｂ：Ｂ＝ＢＵＴＴＯＮ（）
　ＩＦ　ＦＬ＝＝ＲＱ　ＴＨＥＮ　＠ＳＫＩＰ
　ＦＬ＝ＲＱ
　ＯＮ　ＦＬ　ＧＯＳＵＢ　＠ＧＩ，＠ＴＩ
　ＧＯＴＯ　＠ＷＡＩＴ
＠ＳＫＩＰ
　ＯＮ　ＦＬ　ＧＯＳＵＢ　＠ＧＭ，＠ＴＭ
＠ＷＡＩＴ
　ＶＳＹＮＣ　１
ＧＯＴＯ　＠ＬＯＯＰ

’┌───────┐
’│ケ゛－ムメイン│
’└───────┘
＠ＧＭ
ＧＯＳＵＢ　＠ＣＴＲＬ
ＧＯＳＵＢ　＠ＭＯＶＥ
ＲＥＴＵＲＮ

’┌────────┐
’│ケ゛－ムショキカ│
’└────────┘
＠ＧＩ
ＣＬＳ
ＦＯＲ　Ｉ＝０　ＴＯ　ＭＭＡＸ－１
　Ｂ＝ＲＮＤ（２）
　Ｍ（Ｉ，＿Ｂ）＝Ｂ
　Ｂ＝ＲＮＤ（８）＊Ｂ＊１０
　Ｍ（Ｉ，＿Ｍ）＝Ｂ＋ＲＮＤ（１０）＋１
　Ｍ（Ｉ，＿Ｕ）＝－１　：’ＲＮＤ（５）－１
ＮＥＸＴ
’－－－セントウハＧＥＴニスル
Ｍ（０，＿Ｂ）＝６
Ｍ（０，＿Ｍ）＝０
Ｍ（０，＿Ｕ）＝４
ＦＯＲ　Ｉ＝０　ＴＯ　ＭＭＡＸ－１
　ＣＯＬＯＲ　Ｃ（Ｍ（Ｉ，＿Ｕ）＋１）
　ＰＲＩＮＴ　Ｂ＄（Ｍ（Ｉ，＿Ｂ），０）；
ＮＥＸＴ

’－－－
ＦＯＲ　Ｉ＝０　ＴＯ　３
　ＧＯＳＵＢ　＠ＰＵＴＳＴＡＴ
ＮＥＸＴ
ＯＸ＝０
ＧＯＳＵＢ　＠ＰＵＴＭＡＰ
’－－－
ＧＯＳＵＢ　＠ＰＵＴＭＳＧ
Ｗ１＝０：Ｗ２＝０
ＭＶ＝０：ＭＷ＝０：ＵＳ＝０：ＣＷ＝０
ＲＥＴＵＲＮ

’┌────┐
’│イト゛ウ│
’└────┘
＠ＭＯＶＥ
ＩＦ　ＭＶ！＝０　ＧＯＴＯ　＠ＭＳＫＩＰ２
ＳＩ＝ＲＮＤ（６）＋１
ＬＯＣＡＴＥ　３０，２３
ＰＲＩＮＴ　ＳＩ；
ＩＦ　ＵＳ＝＝０　ＧＯＴＯ　＠ＭＢＵＴＡ
’－－－
ＣＷ＝ＣＷ＋１
ＩＦ　ＣＷ＜１６　ＴＨＥＮ　＠ＰＵＴＭＳＧ
ＣＷ＝０
ＧＯＴＯ　＠ＭＳＫＩＰ
’－－－
＠ＭＢＵＴＡ
ＩＦ　Ｂ！＝１６　ＴＨＥＮ　＠ＰＵＴＭＳＧ
’－－－
＠ＭＳＫＩＰ
ＭＶ＝１
’－－－
＠ＭＳＫＩＰ２
ＭＷ＝ＭＷ＋１
’ＩＦ　ＭＷ＜１０　ＴＨＥＮ　＠ＰＵＴＭＳＧ
ＭＷ＝０
’－－－
Ｘ＝Ｕ（ＵＳ，１）：Ｙ＝２＋ＵＳ
ＬＯＣＡＴＥ　Ｘ，Ｙ：ＰＲＩＮＴ”й”
ＣＯＬＯＲ　Ｃ（ＵＳ＋１）
Ｘ＝Ｘ＋１
ＩＦ　Ｘ＞＝ＭＭＡＸ　ＴＨＥＮ　Ｘ＝Ｘ－ＭＭＡＸ
Ｕ（ＵＳ，１）＝Ｘ
ＬＯＣＡＴＥ　Ｘ，Ｙ：ＰＲＩＮＴ”г”
ＯＸ＝Ｘ
’－－－キュウリョウ
ＩＦ　Ｘ！＝０　ＴＨＥＮ　＠ＰＭＰ
Ｕ（ＵＳ，０）＝Ｕ（ＵＳ，０）＋５００
Ｉ＝ＵＳ：ＧＯＳＵＢ　＠ＰＵＴＳＴＡＴ
’－－－
＠ＰＭＰ
ＧＯＳＵＢ　＠ＰＵＴＭＡＰ
ＳＩ＝ＳＩ－１
ＩＦ　ＳＩ！＝０　ＴＨＥＮ　＠ＰＵＴＭＳＧ
’－－－
Ｘ＝Ｕ（ＵＳ，１）
Ｉ＝Ｍ（Ｘ，＿Ｕ）
ＰＲ＝Ｍ（Ｘ，＿Ｍ）
ＭＮ＝Ｕ（ＵＳ，０）
ＩＦ　Ｉ＝＝－１　ＧＯＴＯ　＠ＢＵＹ
ＩＦ　Ｉ＝＝ＵＳ　ＧＯＴＯ　＠ＢＵＹ
ＩＦ　Ｉ＞３　ＧＯＴＯ　＠ＣＮＥＸＴ
’－－－ホカノヒトノトチ
ＧＯＳＵＢ　＠ＣＬＣＯＦＳ
Ｕ（ＵＳ，０）＝ＭＮ－ＰＲ
Ｕ（Ｉ，０）＝Ｕ（Ｉ，０）＋ＰＲ
ＧＯＳＵＢ　＠ＰＵＴＳＴＡＴ
ＧＯＴＯ　＠ＣＮＥＸＴ
’－－－コウニュウテ゛キルカ？
＠ＢＵＹ
ＩＦ　ＭＮ＜ＰＲ　ＧＯＴＯ　＠ＣＮＥＸＴ
’－－－コウニュウスル
ＢＬ＝Ｍ（Ｘ，＿Ｂ）
ＩＦ　ＢＬ＞＝５　ＧＯＴＯ　＠ＣＮＥＸＴ
Ｍ（Ｘ，＿Ｂ）＝ＢＬ＋１
Ｍ（Ｘ，＿Ｕ）＝ＵＳ
Ｕ（ＵＳ，０）＝ＭＮ－ＰＲ
’－－－カカクヘンコウ
Ｍ（Ｘ，＿Ｍ）＝Ｍ（Ｘ，＿Ｍ）＊２
’－－－サイヒョウシ゛
ＧＯＳＵＢ　＠ＰＵＴＭＡＰ
’－－－ツキ゛ノヒトヘ
＠ＣＮＥＸＴ
Ｉ＝ＵＳ：ＧＯＳＵＢ　＠ＰＵＴＳＴＡＴ
ＵＳ＝ＵＳ＋１
ＵＳ＝ＵＳ　ＡＮＤ　３
ＧＯＳＵＢ　＠ＰＭＳＧＣＬＲ
ＭＶ＝０：ＦＷ＝０
’－－－
＠ＰＵＴＭＳＧ
ＦＷ＝ＦＷ＋１：ＩＦ　ＦＷ＞６０　ＴＨＥＮ　ＦＷ＝０
ＩＦ　ＦＷ＞３０　ＴＨＥＮ　＠ＰＭＳＧＣＬＲ
’－－－
ＬＯＣＡＴＥ　０，２３
ＩＦ　ＵＳ＝＝０　ＧＯＴＯ　＠ＰＭＳＧ２
ＰＲＩＮＴ　Ｎ＄（ＵＳ）；”カ゛、サイコロヲフリマス”；
ＲＥＴＵＲＮ
＠ＰＭＳＧ２
ＰＲＩＮＴ”Аホ゛タンテ゛、サイコロヲフッテクタ゛サイ”；
ＲＥＴＵＲＮ
’－－－－
＠ＰＭＳＧＣＬＲ
Ｘ＝０：Ｙ＝２３：Ｅ＝２８：ＧＯＳＵＢ　＠ＣＬＲ
ＲＥＴＵＲＮ

’┌─────┐
’│ハ゛イリツ│
’└─────┘
＠ＣＬＣＯＦＳ
Ｘ１＝Ｘ－１
ＩＦ　Ｘ１＜０　ＴＨＥＮ　Ｘ１＝Ｘ１＋ＭＭＡＸ
Ｘ２＝Ｘ＋１
ＩＦ　Ｘ２＞ＭＭＡＸ－１　ＴＨＥＮ　Ｘ２＝Ｘ２－ＭＭＡＸ
ＩＦ　Ｍ（Ｘ１，＿Ｕ）＝＝Ｉ　ＴＨＥＮ　ＰＲ＝ＰＲ＊２
ＩＦ　Ｍ（Ｘ２，＿Ｕ）＝＝Ｉ　ＴＨＥＮ　ＰＲ＝ＰＲ＊２
ＲＥＴＵＲＮ

’┌────────┐
’│マッフ゜カクニン│
’└────────┘
＠ＣＴＲＬ
ＶＸ＝０
ＩＦ　Ｂ　ＡＮＤ　４　ＴＨＥＮ　ＶＸ＝－１
ＩＦ　Ｂ　ＡＮＤ　８　ＴＨＥＮ　ＶＸ＝１
ＩＦ　ＯＬＤＢ！＝０　ＧＯＴＯ　＠ＣＲＥＰＴ
ＩＦ　ＯＬＤＢ＝＝０　ＴＨＥＮ　Ｗ１＝０：Ｗ２＝０
ＩＦ　ＶＸ！＝０　ＧＯＴＯ　＠ＣＳＫＩＰ
’－－－
＠ＣＲＥＰＴ
ＩＦ　Ｗ１＞＝１５　ＧＯＴＯ　＠ＣＲＥＰ２
Ｗ１＝Ｗ１＋１
ＩＦ　Ｗ１＝＝１５　ＧＯＴＯ　＠ＣＳＫＩＰ
ＲＥＴＵＲＮ
’
＠ＣＲＥＰ２
Ｗ２＝Ｗ２＋１
ＩＦ　Ｗ２＜２　ＴＨＥＮ　ＲＥＴＵＲＮ
Ｗ２＝０
’－－－
＠ＣＳＫＩＰ
ＯＸ＝ＯＸ＋ＶＸ
ＩＦ　ＯＸ＜０　ＴＨＥＮ　ＯＸ＝ＯＸ＋ＭＭＡＸ
ＩＦ　ＯＸ＞ＭＭＡＸ－１　ＴＨＥＮ　ＯＸ＝ＯＸ－ＭＭＡＸ
ＧＯＳＵＢ　＠ＰＵＴＭＡＰ
ＲＥＴＵＲＮ

’－－－
＠ＰＵＴＭＡＰ
Ｘ＝０：Ｙ＝１：Ｅ＝３２：ＧＯＳＵＢ　＠ＣＬＲ
’－－－
ＦＯＲ　Ｉ＝０　ＴＯ　５
　
　’－－－タテモノヒョウシ゛
　Ｘ＝Ｉ＊５＋１
　Ｙ＝６
　Ｏ＝（ＯＸ＋Ｉ）％ＭＭＡＸ
　Ｎ＝Ｍ（Ｏ，＿Ｂ）
　ＣＯＬＯＲ　Ｃ（Ｍ（Ｏ，＿Ｕ）＋１）
　ＦＯＲ　Ｊ＝０　ＴＯ　７
　　ＬＯＣＡＴＥ　Ｘ，Ｊ＋Ｙ
　　ＰＲＩＮＴ　Ｂ＄（Ｎ，Ｊ＋１）
　ＮＥＸＴ
　’－－－
　Ｙ＝ＣＳＲＹ
　ＬＯＣＡＴＥ　Ｏ，０
　ＰＲＩＮＴ　Ｂ＄（Ｎ，０）；
　’－－－
　ＩＦ　Ｏ！＝０　ＧＯＴＯ　＠ＰＭＰＲＩＣＥ
　’
　ＬＯＣＡＴＥ　Ｘ，Ｙ＋０：ＰＲＩＮＴ”ВВВВВ”
　ＬＯＣＡＴＥ　Ｘ，Ｙ＋１：ＰＲＩＮＴ”ВВВВВ”
　ＬＯＣＡＴＥ　Ｘ，Ｙ＋２：ＰＲＩＮＴ”ВВВВВ”
　ＧＯＴＯ　＠ＰＭＳＫＩＰ
　’
＠ＰＭＰＲＩＣＥ　
　ＣＯＬＯＲ　２
　ＬＯＣＡＴＥ　Ｘ，Ｙ＋０：ＰＲＩＮＴ”┌───┐”
　ＬＯＣＡＴＥ　Ｘ，Ｙ＋１：ＰＲＩＮＴ”│　　　│”
　ＬＯＣＡＴＥ　Ｘ＋１，Ｙ＋１
　ＰＲＩＮＴ　Ｍ（Ｏ，＿Ｍ）
　ＬＯＣＡＴＥ　Ｘ，Ｙ＋２：ＰＲＩＮＴ”└───┘”
　’
＠ＰＭＳＫＩＰ
　ＬＯＣＡＴＥ　Ｏ，１
　ＰＲＩＮＴ　”─”
　
ＮＥＸＴ
ＣＯＬＯＲ　０
ＲＥＴＵＲＮ

’－－－
＠ＰＵＴＳＴＡＴ
ＣＯＬＯＲ　Ｃ（Ｉ＋１）
Ｘ＝Ｉ＊８：Ｙ＝１７
ＬＯＣＡＴＥ　Ｘ，Ｙ＋０：ＰＲＩＮＴ”┌──────┐”；
ＬＯＣＡＴＥ　Ｘ，Ｙ＋１：ＰＲＩＮＴ”│”；
ＰＲＩＮＴ　Ｉ＋１；”：”；
ＰＲＩＮＴ　Ｎ＄（Ｉ）；”│”；
ＬＯＣＡＴＥ　Ｘ，Ｙ＋２：ＰＲＩＮＴ”├──────┤”；
ＬＯＣＡＴＥ　Ｘ，Ｙ＋３：ＰＲＩＮＴ”│”；
Ｃ＄＝”　　　　　　”＋ＳＴＲ＄（Ｕ（Ｉ，０））
Ｃ＄＝ＭＩＤ＄（Ｃ＄，ＬＥＮ（Ｃ＄）－６，６）
ＰＲＩＮＴ　Ｃ＄；”│”；
ＬＯＣＡＴＥ　Ｘ，Ｙ＋４：ＰＲＩＮＴ”│　　　　　　│”；
ＬＯＣＡＴＥ　Ｘ，Ｙ＋５：ＰＲＩＮＴ”└──────┘”；
’－－－
Ｘ＝Ｕ（Ｉ，１）
ＬＯＣＡＴＥ　Ｘ，Ｉ＋２
ＰＲＩＮＴ”г”
’－－－
ＣＯＬＯＲ　０
ＲＥＴＵＲＮ

’－－－
＠ＣＬＲ
ＬＯＣＡＴＥ　Ｘ，Ｙ
ＦＯＲ　Ｉ＝０　ＴＯ　Ｅ－１
　ＰＲＩＮＴ”　”；
ＮＥＸＴ
ＲＥＴＵＲＮ

’
’
’
＠ＴＩ
ＣＬＳ
ＬＯＣＡＴＥ　０，７
ＰＲＩＮＴ”　　　┌───┐┌┐　┌┐┌──┐　┌───┐　┌───┐”
ＰＲＩＮＴ”　　　│┌──┘││　│││┌┐└┐│┌─┐│　└──┐│”
ＰＲＩＮＴ”　　　│└──┐││　││││└┐│││　││　┌──┘│”
ＰＲＩＮＴ”　　　│┌──┘││　││││┌┘│││　││　└──┐│”
ＰＲＩＮＴ”　　　││　　　│└─┘││└┘┌┘│└─┘│　┌──┘│”
ＰＲＩＮＴ”　　　└┘　　　└───┘└──┘　└───┘　└───┘”
ＬＯＣＡＴＥ　８，１６
ＰＲＩＮＴ”ＰＵＳＨ　ＡＮＹ　ＢＵＴＴＯＮ”
ＬＯＣＡＴＥ　４，２２
ＰＲＩＮＴ”（Ｃ）２０１１　ＳｍｉｌｅＢｏｏｍ　Ｃｏ．Ｌｔｄ．”
ＲＥＴＵＲＮ
’
’
’
＠ＴＭ
ＩＦ　ＯＬＤＢ！＝０　ＴＨＥＮ　ＲＥＴＵＲＮ
ＩＦ　Ｂ＝＝０　ＴＨＥＮ　ＲＥＴＵＲＮ
’－－－
ＲＱ＝０
ＲＥＴＵＲＮ